[build] Add the generation of introspection files

This feature depends on the --add-init-section argument of g-ir-scanner
which is available since mid-v0.6.8.

6 files changed, 147 insertions, 0 deletions

diff --git a/.gitignore b/.gitignore
index 695910f..6d5279d 100644
--- a/.gitignore
+++ b/.gitignore
@@ -1,6 +1,8 @@
+*.gir
 *.la
 *.lo
 *.o
+*.typelib
 .deps
 .libs
 Makefile
diff --git a/build/autotools/.gitignore b/build/autotools/.gitignore
index 8cc23f6..55b3560 100644
--- a/build/autotools/.gitignore
+++ b/build/autotools/.gitignore
@@ -1,6 +1,7 @@
 *.m4
 !as-compiler-flag.m4
 !dolt.m4
+!introspection.m4
 !shave.m4
 shave
 shave-libtool
diff --git a/build/autotools/Makefile.am b/build/autotools/Makefile.am
index 9495143..712cfbf 100644
--- a/build/autotools/Makefile.am
+++ b/build/autotools/Makefile.am
@@ -3,6 +3,7 @@ NULL = #
 EXTRA_DIST = \
 	as-compiler-flag.m4	\
 	dolt.m4			\
+	introspection.m4	\
 	shave.in		\
 	shave-libtool.in	\
 	shave.m4		\
diff --git a/build/autotools/introspection.m4 b/build/autotools/introspection.m4
new file mode 100644
index 0000000..bb3a0da
--- /dev/null
+++ b/build/autotools/introspection.m4
@@ -0,0 +1,88 @@
+dnl -*- mode: autoconf -*-
+dnl Copyright 2009 Johan Dahlin
+dnl
+dnl This file is free software; the author(s) gives unlimited
+dnl permission to copy and/or distribute it, with or without
+dnl modifications, as long as this notice is preserved.
+dnl
+
+# serial 1
+
+m4_define([_GOBJECT_INTROSPECTION_CHECK_INTERNAL],
+[
+    AC_BEFORE([AC_PROG_LIBTOOL],[$0])dnl setup libtool first
+    AC_BEFORE([AM_PROG_LIBTOOL],[$0])dnl setup libtool first
+    AC_BEFORE([LT_INIT],[$0])dnl setup libtool first
+
+    dnl enable/disable introspection
+    m4_if([$2], [require],
+    [dnl
+        enable_introspection=yes
+    ],[dnl
+        AC_ARG_ENABLE(introspection,
+                  AS_HELP_STRING([--enable-introspection[=@<:@no/auto/yes@:>@]],
+                                 [Enable introspection for this build]),,
+                                 [enable_introspection=auto])
+    ])dnl
+
+    AC_MSG_CHECKING([for gobject-introspection])
+
+    dnl presence/version checking
+    AS_CASE([$enable_introspection],
+    [no], [dnl
+        found_introspection="no (disabled, use --enable-introspection to enable)"
+    ],dnl
+    [yes],[dnl
+        PKG_CHECK_EXISTS([gobject-introspection-1.0],,
+                         AC_MSG_ERROR([gobject-introspection-1.0 is not installed]))
+        PKG_CHECK_EXISTS([gobject-introspection-1.0 >= $1],
+                         found_introspection=yes,
+                         AC_MSG_ERROR([You need to have gobject-introspection >= $1 installed to build AC_PACKAGE_NAME]))
+    ],dnl
+    [auto],[dnl
+        PKG_CHECK_EXISTS([gobject-introspection-1.0 >= $1], found_introspection=yes, found_introspection=no)
+    ],dnl
+    [dnl
+        AC_MSG_ERROR([invalid argument passed to --enable-introspection, should be one of @<:@no/auto/yes@:>@])
+    ])dnl
+
+    AC_MSG_RESULT([$found_introspection])
+
+    INTROSPECTION_SCANNER=
+    INTROSPECTION_COMPILER=
+    INTROSPECTION_GENERATE=
+    INTROSPECTION_GIRDIR=
+    INTROSPECTION_TYPELIBDIR=
+    if test "x$found_introspection" = "xyes"; then
+       INTROSPECTION_SCANNER=`$PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0`
+       INTROSPECTION_COMPILER=`$PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0`
+       INTROSPECTION_GENERATE=`$PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0`
+       INTROSPECTION_GIRDIR=`$PKG_CONFIG --variable=girdir gobject-introspection-1.0`
+       INTROSPECTION_TYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
+    fi
+    AC_SUBST(INTROSPECTION_SCANNER)
+    AC_SUBST(INTROSPECTION_COMPILER)
+    AC_SUBST(INTROSPECTION_GENERATE)
+    AC_SUBST(INTROSPECTION_GIRDIR)
+    AC_SUBST(INTROSPECTION_TYPELIBDIR)
+
+    AM_CONDITIONAL(HAVE_INTROSPECTION, test "x$found_introspection" = "xyes")
+])
+
+
+dnl Usage:
+dnl   GOBJECT_INTROSPECTION_CHECK([minimum-g-i-version])
+
+AC_DEFUN([GOBJECT_INTROSPECTION_CHECK],
+[
+  _GOBJECT_INTROSPECTION_CHECK_INTERNAL([$1])
+])
+
+dnl Usage:
+dnl   GOBJECT_INTROSPECTION_REQUIRE([minimum-g-i-version])
+
+
+AC_DEFUN([GOBJECT_INTROSPECTION_REQUIRE],
+[
+  _GOBJECT_INTROSPECTION_CHECK_INTERNAL([$1], [require])
+])
diff --git a/clutter-gst/Makefile.am b/clutter-gst/Makefile.am
index 0074d8e..5c5358f 100644
--- a/clutter-gst/Makefile.am
+++ b/clutter-gst/Makefile.am
@@ -1,7 +1,10 @@
 NULL = #
+QUIET_GEN = $(Q:@=@echo '  GEN   '$@;)
 
 SUBDIRS = shaders
 
+CLEANFILES = #
+
 source_h = 					\
 	$(srcdir)/clutter-gst-audio.h 		\
 	$(srcdir)/clutter-gst-util.h		\
@@ -50,3 +53,50 @@ libclutter_gst_@CLUTTER_GST_MAJORMINOR@_la_LDFLAGS = @CLUTTER_GST_LT_LDFLAGS@
 
 cluttergstheadersdir = $(includedir)/clutter-@CLUTTER_API_VERSION@/clutter-gst
 cluttergstheaders_HEADERS = $(source_h) clutter-gst.h
+
+#
+# Introspection data
+#
+
+if HAVE_INTROSPECTION
+BUILT_GIRSOURCES =
+
+ClutterGst-@CLUTTER_GST_API_VERSION@.gir: $(INTROSPECTION_SCANNER) libclutter-gst-@CLUTTER_GST_API_VERSION@.la
+	$(QUIET_GEN)$(INTROSPECTION_SCANNER) -v \
+		--namespace ClutterGst --nsversion=@CLUTTER_GST_API_VERSION@ \
+		$(INCLUDES) \
+		--add-include-path=$(srcdir) --add-include=path=. \
+		--c-include="clutter-gst/clutter-gst.h" \
+		--include=GObject-2.0 \
+		--include=Clutter-1.0 \
+		--include=Gst-0.10 \
+		--include=GstBase-0.10 \
+		--include=GstInterfaces-0.10 \
+		--include=GstVideo-0.10 \
+		--include=GstAudio-0.10 \
+		--add-init-section="clutter_gst_init(0,NULL);" \
+		--library=clutter-gst-@CLUTTER_GST_API_VERSION@ \
+		--libtool="$(top_builddir)/libtool" \
+		--output $@ \
+		--pkg gobject-2.0 \
+		--pkg clutter-1.0 \
+		--pkg gstreamer-0.10 \
+		--pkg gstreamer-base-0.10 \
+		$(cluttergstheaders_HEADERS) \
+		$(source_c)
+
+BUILT_GIRSOURCES += ClutterGst-@CLUTTER_GST_API_VERSION@.gir
+
+# INTROSPECTION_GIRDIR/INTROSPECTION_TYPELIBDIR aren't the right place to
+# install anything - we need to install inside our prefix.
+girdir = $(datadir)/gir-1.0
+gir_DATA = $(BUILT_GIRSOURCES)
+
+typelibsdir = $(libdir)/girepository-1.0/
+typelibs_DATA = $(BUILT_GIRSOURCES:.gir=.typelib)
+
+%.typelib: %.gir $(INTROSPECTION_COMPILER)
+	$(QUIET_GEN)$(INTROSPECTION_COMPILER) --includedir=$(srcdir) --includedir=. $(INTROSPECTION_COMPILER_OPTS) $< -o $(builddir)/$(@F)
+
+CLEANFILES += $(BUILT_GIRSOURCES) $(typelibs_DATA)
+endif
diff --git a/configure.ac b/configure.ac
index a582a45..71f6719 100644
--- a/configure.ac
+++ b/configure.ac
@@ -167,6 +167,10 @@ AM_CONDITIONAL([BUILD_GTK_DOC],
 
 dnl ========================================================================
 
+GOBJECT_INTROSPECTION_CHECK([0.6.8])
+
+dnl ========================================================================
+
 AC_SUBST(GCC_FLAGS)
 AC_SUBST(GST_CFLAGS)
 AC_SUBST(GST_LIBS)
@@ -207,4 +211,5 @@ echo "              Cg compiler:   ${have_cgc}"
 echo ""
 echo "              debug level:   ${enable_debug}"
 echo "  Build API documentation:   ${enable_gtk_doc}"
+echo "       Introspection data:   ${enable_introspection}"
 echo ""