1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
|
AC_PREREQ([2.60])
m4_define([gsd_api_version_major],[2])
m4_define([gsd_api_version_minor],[0])
m4_define([gsd_api_version],[gsd_api_version_major.gsd_api_version_minor])
AC_INIT([gnome-settings-daemon],
[2.22.1],
[http://bugzilla.gnome.org/enter_bug.cgi?product=gnome-settings-daemon])
AC_CONFIG_SRCDIR([gnome-settings-daemon/gnome-settings-manager.c])
AM_INIT_AUTOMAKE([1.9 no-dist-gzip dist-bzip2 tar-ustar])
AM_MAINTAINER_MODE
AC_STDC_HEADERS
AC_PROG_CXX
AM_PROG_CC_C_O
AC_PROG_LIBTOOL
AC_HEADER_STDC
AC_SUBST(VERSION)
AC_CONFIG_HEADERS([config.h])
IT_PROG_INTLTOOL([0.35.0])
GETTEXT_PACKAGE=gnome-settings-daemon
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Name of default gettext domain])
AM_GLIB_GNU_GETTEXT
GSD_INTLTOOL_PLUGIN_RULE='%.gnome-settings-plugin: %.gnome-settings-plugin.in $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
AC_SUBST([GSD_INTLTOOL_PLUGIN_RULE])
dnl ---------------------------------------------------------------------------
dnl - Dependencies
dnl ---------------------------------------------------------------------------
DBUS_GLIB_REQUIRED_VERSION=0.74
GLIB_REQUIRED_VERSION=2.13.0
GTK_REQUIRED_VERSION=2.10.0
GCONF_REQUIRED_VERSION=2.6.1
GIO_REQUIRED_VERSION=2.15.0
GNOME_DESKTOP_REQUIRED_VERSION=2.21.4
EXTRA_COMPILE_WARNINGS(yes)
PKG_CHECK_MODULES(SETTINGS_DAEMON,
gtk+-2.0 >= $GTK_REQUIRED_VERSION
gconf-2.0 >= $GCONF_REQUIRED_VERSION
gmodule-2.0
dbus-glib-1 >= $DBUS_GLIB_REQUIRED_VERSION
libgnome-2.0
)
AC_SUBST(SETTINGS_DAEMON_CFLAGS)
AC_SUBST(SETTINGS_DAEMON_LIBS)
PKG_CHECK_MODULES(SETTINGS_PLUGIN,
gtk+-2.0 >= $GTK_REQUIRED_VERSION
gconf-2.0 >= $GCONF_REQUIRED_VERSION
gnome-desktop-2.0 >= $GNOME_DESKTOP_REQUIRED_VERSION
gio-2.0 >= $GIO_REQUIRED_VERSION
libglade-2.0 >= 2.0.0
dbus-glib-1 >= $DBUS_GLIB_REQUIRED_VERSION
)
AC_SUBST(SETTINGS_PLUGIN_CFLAGS)
AC_SUBST(SETTINGS_PLUGIN_LIBS)
PKG_CHECK_MODULES(GNOME, libgnome-2.0 libgnomeui-2.0)
PKG_CHECK_MODULES(LIBBACKGROUND, glib-2.0 gobject-2.0 gdk-2.0 gconf-2.0)
PKG_CHECK_MODULES(LIBSOUNDS, gio-2.0 libgnome-2.0 libgnomeui-2.0)
GSD_PLUGIN_LDFLAGS="-export_dynamic -module -avoid-version -no-undefined"
AC_SUBST([GSD_PLUGIN_LDFLAGS])
AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
AC_PATH_XTRA
AC_PATH_PROG(GCONFTOOL, gconftool-2)
AM_GCONF_SOURCE_2
dnl ---------------------------------------------------------------------------
dnl - Check for D-Bus
dnl ---------------------------------------------------------------------------
dnl - Are we specifying a different dbus root ?
AC_ARG_WITH(dbus-sys,
[AC_HELP_STRING([--with-dbus-sys=<dir>],
[where D-BUS system.d directory is])])
AC_ARG_WITH(dbus-services,
[AC_HELP_STRING([--with-dbus-services=<dir>],
[where D-BUS services directory is])])
if ! test -z "$with_dbus_sys" ; then
DBUS_SYS_DIR="$with_dbus_sys"
else
DBUS_SYS_DIR='${sysconfdir}/dbus-1/system.d'
fi
AC_SUBST(DBUS_SYS_DIR)
dnl ---------------------------------------------------------------------------
dnl - X11 stuff
dnl ---------------------------------------------------------------------------
# Like AC_CHECK_HEADER, but it uses the already-computed -I directories.
#
AC_DEFUN([AC_CHECK_X_HEADER], [
ac_save_CPPFLAGS="$CPPFLAGS"
if test \! -z "$includedir" ; then
CPPFLAGS="$CPPFLAGS -I$includedir"
fi
CPPFLAGS="$CPPFLAGS $X_CFLAGS"
AC_CHECK_HEADER([$1],[$2],[$3],[$4])
CPPFLAGS="$ac_save_CPPFLAGS"])
# Like AC_CHECK_LIB, but it uses the already-computed -I and -L directories.
# Use this sparingly; it probably doesn't work very well on X programs.
#
AC_DEFUN([AC_CHECK_X_LIB], [
ac_save_CPPFLAGS="$CPPFLAGS"
ac_save_LDFLAGS="$LDFLAGS"
# ac_save_LIBS="$LIBS"
if test \! -z "$includedir" ; then
CPPFLAGS="$CPPFLAGS -I$includedir"
fi
# note: $X_CFLAGS includes $x_includes
CPPFLAGS="$CPPFLAGS $X_CFLAGS"
if test \! -z "$libdir" ; then
LDFLAGS="$LDFLAGS -L$libdir"
fi
# note: $X_LIBS includes $x_libraries
LDFLAGS="$LDFLAGS $ALL_X_LIBS"
AC_CHECK_LIB([$1], [$2], [$3], [$4], [$5])
CPPFLAGS="$ac_save_CPPFLAGS"
LDFLAGS="$ac_save_LDFLAGS"
# LIBS="$ac_save_LIBS"
])
AC_PATH_XTRA
ALL_X_LIBS="$X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS"
dnl ---------------------------------------------------------------------------
dnl - XInput
dnl ---------------------------------------------------------------------------
have_xinput=no
AC_CHECK_LIB(Xi, XListInputDevices,
[AC_CHECK_HEADER(X11/extensions/XInput.h,
have_xinput=yes
XINPUT_LIBS="-lXi"
AC_DEFINE(HAVE_XINPUT, 1, [Define if XInput extension is available]),
:, [#include <X11/Xlib.h>])], : ,
-lXi $x_libs)
AM_CONDITIONAL(HAVE_XINPUT, [test $have_xinput = yes])
AC_SUBST(XINPUT_LIBS)
dnl ---------------------------------------------------------------------------
dnl - XRandR
dnl ---------------------------------------------------------------------------
have_randr=no
AC_CHECK_LIB(Xrandr, XRRUpdateConfiguration,
[AC_CHECK_HEADER(X11/extensions/Xrandr.h,
have_randr=yes
RANDR_LIBS="-lXrandr -lXrender"
AC_DEFINE(HAVE_RANDR, 1, [Define if Xrandr extension is available]),
:, [#include <X11/Xlib.h>])], : ,
-lXrandr -lXrender $x_libs)
AC_SUBST(RANDR_LIBS)
dnl ---------------------------------------------------------------------------
dnl - XFT2
dnl ---------------------------------------------------------------------------
if $PKG_CONFIG --exists xft; then
AC_DEFINE(HAVE_XFT2, 1, [Define if Xft functionality is available])
fi
dnl ---------------------------------------------------------------------------
dnl - Keyboard plugin stuff
dnl ---------------------------------------------------------------------------
AC_CHECK_HEADERS([X11/Xlib.h])
AC_CHECK_X_LIB(Xxf86misc, XF86MiscQueryExtension, [
AC_CHECK_HEADERS([X11/extensions/xf86misc.h], [XF86MISC_LIBS="-lXxf86misc"],[],
[#if HAVE_X11_XLIB_H
#include <X11/Xlib.h>
#endif
])], [true], -lXext -lX11)
AC_SUBST(XF86MISC_LIBS)
AC_CHECK_HEADERS(X11/extensions/XKB.h)
PKG_CHECK_MODULES(LIBGNOMEKBD, [libgnomekbd >= 2.21.4 libxklavier >= 3.3])
AC_SUBST(LIBGNOMEKBD_CFLAGS)
AC_SUBST(LIBGNOMEKBD_LIBS)
dnl ==============================================
dnl Esd section
dnl ==============================================
AC_ARG_ENABLE(esd,
AC_HELP_STRING([--disable-esd],
[turn off ESD audio support]),
[case "${enableval}" in
yes) WANT_ESD=yes ;;
no) WANT_ESD=no ;;
*) AC_MSG_ERROR(bad value ${enableval} for --disable-esd) ;;
esac],
[WANT_ESD=yes]) dnl Default value
if test x$WANT_ESD = xyes ; then
PKG_CHECK_MODULES(ESD, esound >= 0.2.28,
AC_DEFINE(HAVE_ESD, 1, [Define if ESD sound server should be used]),
AC_MSG_RESULT([disabled]))
fi
AC_SUBST(ESD_CFLAGS)
AC_SUBST(ESD_LIBS)
dnl ==============================================
dnl GStreamer section
dnl ==============================================
GST_MAJORMINOR=auto
AC_ARG_ENABLE(gstreamer,
AC_HELP_STRING([--enable-gstreamer],[use gstreamer if available (and optionally specify a version)]),
[case "${enableval}" in
yes) ENABLE_GSTREAMER=yes ;;
0.10) ENABLE_GSTREAMER=yes && GST_MAJORMINOR=0.10 ;;
no) ENABLE_GSTREAMER=no ;;
*) AC_MSG_ERROR([
*** Bad value ${enableval} for --enable-gstreamer
*** Please use one of the following:
*** --enable-gstreamer=0.10
]) ;;
esac],
[ENABLE_GSTREAMER=yes]) dnl Default value
have_gstreamer=no
if test "x$ENABLE_GSTREAMER" = "xyes"; then
GST_REQS=0.10.1.2
PKGS="gstreamer-0.10 >= $GST_REQS gstreamer-plugins-base-0.10 >= $GST_REQS"
PKG_CHECK_MODULES(GST, $PKGS, have_gstreamer=yes,
AC_MSG_RESULT([no]))
GST_LIBS="$GST_LIBS -lgstinterfaces-0.10 -lgstaudio-0.10"
else
AC_MSG_NOTICE([*** GStreamer support disabled ***])
fi
AM_CONDITIONAL(HAVE_GSTREAMER, test "x$have_gstreamer" = "xyes")
AC_SUBST(GST_LIBS)
AC_SUBST(GST_CFLAGS)
dnl ==============================================
dnl OSS section
dnl ==============================================
have_oss=no
if test "x$have_gstreamer" != "xyes"; then
AC_TRY_COMPILE([
#ifdef __NetBSD__
#include <sys/param.h>
#include <sys/sysctl.h>
#include <soundcard.h>
#else
#include <sys/soundcard.h>
#endif
],[
int arg = SNDCTL_DSP_SETFRAGMENT;
],[
have_oss=yes
])
AC_MSG_CHECKING(for OSS audio support)
AC_MSG_RESULT($have_oss)
fi
AM_CONDITIONAL(HAVE_OSS, test x"$have_oss" = "xyes")
dnl ==============================================
dnl ALSA section
dnl ==============================================
have_alsa=no
if test "x$have_gstreamer" != "xyes"; then
AC_ARG_ENABLE(alsa,
AC_HELP_STRING([--disable-alsa],
[turn off ALSA audio support]),
[case "${enableval}" in
yes) WANT_ALSA=yes ;;
no) WANT_ALSA=no ;;
*) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
esac],
[WANT_ALSA=yes]) dnl Default value
if test x$WANT_ALSA = xyes ; then
PKG_CHECK_MODULES(ALSA, alsa >= 0.9.0,
have_alsa=yes,
AC_MSG_RESULT([disabled]))
fi
AC_SUBST(ALSA_LIBS)
AC_SUBST(ALSA_CFLAGS)
fi
AM_CONDITIONAL(HAVE_ALSA, test x"$have_alsa" = "xyes")
dnl ==============================================
dnl IBM Thinkpad support
dnl ==============================================
AC_ARG_ENABLE(thinkpad,
AC_HELP_STRING([--disable-thinkpad],
[disable IBM Thinkpad hardware volume button support]),
[case "${enableval}" in
yes) WANT_THINKPAD=yes ;;
no) WANT_THINKPAD=no ;;
*) AC_MSG_ERROR(bad value ${enableval} for --enable-thinkpad) ;;
esac],
[WANT_THINKPAD=yes]) dnl Default value
if test "x$WANT_THINKPAD" = xyes; then
AC_DEFINE(ENABLE_IBM_THINKPAD, 1, [Define to enable Thinkpad hardware volume buttons support])
fi
AM_CONDITIONAL(ENABLE_IBM_THINKPAD, test "x$WANT_THINKPAD" = "xyes")
# ---------------------------------------------------------------------------
# Enable Profiling
# ---------------------------------------------------------------------------
AC_ARG_ENABLE(profiling,
[AC_HELP_STRING([--enable-profiling],
[turn on profiling])],
, enable_profiling=no)
if test "x$enable_profiling" = "xyes"; then
AC_DEFINE(ENABLE_PROFILING,1,[enable profiling])
fi
# ---------------------------------------------------------------------------
# Plugins
# ---------------------------------------------------------------------------
plugindir='$(libdir)/gnome-settings-daemon-gsd_api_version'
AC_SUBST([plugindir])
dnl ---------------------------------------------------------------------------
dnl - Finish
dnl ---------------------------------------------------------------------------
# Turn on the additional warnings last, so warnings don't affect other tests.
AC_ARG_ENABLE(more-warnings,
[AC_HELP_STRING([--enable-more-warnings],
[Maximum compiler warnings])],
set_more_warnings="$enableval",[
if test -d $srcdir/.svn; then
set_more_warnings=yes
else
set_more_warnings=no
fi
])
AC_MSG_CHECKING(for more warnings)
if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
AC_MSG_RESULT(yes)
CFLAGS="\
-Wall \
-Wchar-subscripts -Wmissing-declarations -Wmissing-prototypes \
-Wnested-externs -Wpointer-arith \
-Wcast-align -Wsign-compare \
$CFLAGS"
for option in -Wno-strict-aliasing -Wno-sign-compare; do
SAVE_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $option"
AC_MSG_CHECKING([whether gcc understands $option])
AC_TRY_COMPILE([], [],
has_option=yes,
has_option=no,)
if test $has_option = no; then
CFLAGS="$SAVE_CFLAGS"
fi
AC_MSG_RESULT($has_option)
unset has_option
unset SAVE_CFLAGS
done
unset option
else
AC_MSG_RESULT(no)
fi
#
# Enable Debug
#
AC_ARG_ENABLE(debug,
[AC_HELP_STRING([--enable-debug],
[turn on debugging])],
, enable_debug=yes)
if test "$enable_debug" = "yes"; then
DEBUG_CFLAGS="-DG_ENABLE_DEBUG"
else
if test "x$enable_debug" = "xno"; then
DEBUG_CFLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
else
DEBUG_CFLAGS=""
fi
fi
AC_SUBST(DEBUG_CFLAGS)
AC_OUTPUT([
Makefile
gnome-settings-daemon/Makefile
plugins/Makefile
plugins/a11y-keyboard/Makefile
plugins/background/Makefile
plugins/background/libbackground/Makefile
plugins/clipboard/Makefile
plugins/dummy/Makefile
plugins/font/Makefile
plugins/housekeeping/Makefile
plugins/keybindings/Makefile
plugins/keyboard/Makefile
plugins/media-keys/Makefile
plugins/media-keys/actions/Makefile
plugins/mouse/Makefile
plugins/screensaver/Makefile
plugins/sound/Makefile
plugins/sound/libsounds/Makefile
plugins/typing-break/Makefile
plugins/xrandr/Makefile
plugins/xrdb/Makefile
plugins/xrdb/data/Makefile
plugins/xsettings/Makefile
data/Makefile
data/gnome-settings-daemon.pc
data/gnome-settings-daemon-uninstalled.pc
po/Makefile.in
])
dnl ---------------------------------------------------------------------------
dnl - Show summary
dnl ---------------------------------------------------------------------------
echo "
gnome-settings-daemon $VERSION
=============================
prefix: ${prefix}
exec_prefix: ${exec_prefix}
libdir: ${libdir}
bindir: ${bindir}
sbindir: ${sbindir}
sysconfdir: ${sysconfdir}
sysconfsubdir: ${sysconfsubdir}
localstatedir: ${localstatedir}
plugindir: ${plugindir}
datadir: ${datadir}
source code location: ${srcdir}
compiler: ${CC}
cflags: ${CFLAGS}
Maintainer mode: ${USE_MAINTAINER_MODE}
dbus-1 system.d dir: ${DBUS_SYS_DIR}
OSS support: ${have_oss}
ALSA support: ${have_alsa}
GStreamer support: ${have_gstreamer}
ESD support: ${WANT_ESD}
Profiling support: ${enable_profiling}
"
|
