1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
@ ARM mpn_add -- Add two limb vectors of the same length > 0 and store sum in
@ a third limb vector.
@ Contributed by Robert Harley.
@ Copyright (C) 1997, 2000 Free Software Foundation, Inc.
@ This file is part of the GNU MP Library.
@ The GNU MP Library is free software; you can redistribute it and/or modify
@ it under the terms of the GNU Library General Public License as published by
@ the Free Software Foundation; either version 2 of the License, or (at your
@ option) any later version.
@ The GNU MP Library is distributed in the hope that it will be useful, but
@ WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
@ or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public
@ License for more details.
@ You should have received a copy of the GNU Library General Public License
@ along with the GNU MP Library; see the file COPYING.LIB. If not, write to
@ the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
@ MA 02111-1307, USA.
#define s r0
#define a r1
#define b r2
#define n r3
#define sl r10 /* Do not use, reserved for PIC. */
#define fp r11
#define ip r12
#define sp r13
#define lr r14
#define pc r15
.text
.align 0
.global __gmpn_add_n
.type __gmpn_add_n,%function
__gmpn_add_n:
stmfd sp!, { r8, r9, lr }
movs n, n, lsr #1
bcc Lskip1
ldr ip, [a], #4
ldr lr, [b], #4
adds ip, ip, lr
str ip, [s], #4
Lskip1:
tst n, #1
beq Lskip2
ldmia a!, { r8, r9 }
ldmia b!, { ip, lr }
adcs r8, r8, ip
adcs r9, r9, lr
stmia s!, { r8, r9 }
Lskip2:
bics n, n, #1
beq Lreturn
stmfd sp!, { r4, r5, r6, r7 }
LLoop:
ldmia a!, { r4, r5, r6, r7 }
ldmia b!, { r8, r9, ip, lr }
adcs r4, r4, r8
adcs r5, r5, r9
adcs r6, r6, ip
adcs r7, r7, lr
stmia s!, { r4, r5, r6, r7 }
sub n, n, #2
teq n, #0
bne LLoop
ldmfd sp!, { r4, r5, r6, r7 }
Lreturn:
adc r0, n, #0
ldmfd sp!, { r8, r9, pc }^
Lend:
.size __gmpn_add_n, Lend - __gmpn_add_n
|
