1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
|
/* wcsrchr with SSSE3
Copyright (C) 2011-2017 Free Software Foundation, Inc.
Contributed by Intel Corporation.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, see
<http://www.gnu.org/licenses/>. */
#include <sysdep.h>
.text
ENTRY (__wcsrchr_old_2)
movd %esi, %xmm1
mov %edi, %ecx
punpckldq %xmm1, %xmm1
pxor %xmm2, %xmm2
punpckldq %xmm1, %xmm1
and $63, %ecx
cmp $48, %ecx
ja L(crosscache)
movdqu (%rdi), %xmm0
pcmpeqd %xmm0, %xmm2
pcmpeqd %xmm1, %xmm0
pmovmskb %xmm2, %ecx
pmovmskb %xmm0, %eax
add $16, %rdi
test %eax, %eax
jnz L(unaligned_match1)
test %ecx, %ecx
jnz L(return_null)
and $-16, %rdi
xor %r8d, %r8d
jmp L(loop)
.p2align 4
L(unaligned_match1):
test %ecx, %ecx
jnz L(prolog_find_zero_1)
mov %eax, %r8d
mov %rdi, %rsi
and $-16, %rdi
jmp L(loop)
.p2align 4
L(crosscache):
and $15, %ecx
and $-16, %rdi
pxor %xmm3, %xmm3
movdqa (%rdi), %xmm0
pcmpeqd %xmm0, %xmm3
pcmpeqd %xmm1, %xmm0
pmovmskb %xmm3, %edx
pmovmskb %xmm0, %eax
shr %cl, %edx
shr %cl, %eax
add $16, %rdi
test %eax, %eax
jnz L(unaligned_match)
test %edx, %edx
jnz L(return_null)
xor %r8d, %r8d
jmp L(loop)
.p2align 4
L(unaligned_match):
test %edx, %edx
jnz L(prolog_find_zero)
mov %eax, %r8d
lea (%rdi, %rcx), %rsi
/* Loop start on aligned string. */
.p2align 4
L(loop):
movdqa (%rdi), %xmm0
pcmpeqd %xmm0, %xmm2
add $16, %rdi
pcmpeqd %xmm1, %xmm0
pmovmskb %xmm2, %ecx
pmovmskb %xmm0, %eax
or %eax, %ecx
jnz L(matches)
movdqa (%rdi), %xmm3
pcmpeqd %xmm3, %xmm2
add $16, %rdi
pcmpeqd %xmm1, %xmm3
pmovmskb %xmm2, %ecx
pmovmskb %xmm3, %eax
or %eax, %ecx
jnz L(matches)
movdqa (%rdi), %xmm4
pcmpeqd %xmm4, %xmm2
add $16, %rdi
pcmpeqd %xmm1, %xmm4
pmovmskb %xmm2, %ecx
pmovmskb %xmm4, %eax
or %eax, %ecx
jnz L(matches)
movdqa (%rdi), %xmm5
pcmpeqd %xmm5, %xmm2
add $16, %rdi
pcmpeqd %xmm1, %xmm5
pmovmskb %xmm2, %ecx
pmovmskb %xmm5, %eax
or %eax, %ecx
jz L(loop)
.p2align 4
L(matches):
test %eax, %eax
jnz L(match)
L(return_value):
test %r8d, %r8d
jz L(return_null)
mov %r8d, %eax
mov %rsi, %rdi
and $0x11111111, %eax
bsr %eax, %eax
lea -16(%rdi, %rax), %rax
ret
.p2align 4
L(match):
pmovmskb %xmm2, %ecx
test %ecx, %ecx
jnz L(find_zero)
mov %eax, %r8d
mov %rdi, %rsi
jmp L(loop)
.p2align 4
L(find_zero):
test $15, %cl
jnz L(find_zero_in_first_wchar)
test %cl, %cl
jnz L(find_zero_in_second_wchar)
test $15, %ch
jnz L(find_zero_in_third_wchar)
and $1 << 13 - 1, %eax
jz L(return_value)
and $0x11111111, %eax
bsr %eax, %eax
lea -16(%rdi, %rax), %rax
ret
.p2align 4
L(find_zero_in_first_wchar):
test $1, %eax
jz L(return_value)
lea -16(%rdi), %rax
ret
.p2align 4
L(find_zero_in_second_wchar):
and $1 << 5 - 1, %eax
jz L(return_value)
test $15 << 4, %al
jnz L(match_second_wchar)
lea -16(%rdi), %rax
ret
.p2align 4
L(find_zero_in_third_wchar):
and $1 << 9 - 1, %eax
jz L(return_value)
test %ah, %ah
jnz L(match_third_wchar)
test $15 << 4, %al
jnz L(match_second_wchar)
lea -16(%rdi), %rax
ret
.p2align 4
L(prolog_find_zero):
add %rcx, %rdi
mov %edx, %ecx
L(prolog_find_zero_1):
and $0x11111111, %ecx
and $0x11111111, %eax
bsf %ecx, %ecx
bsr %eax, %eax
cmp %eax, %ecx
jl L(return_null)
lea -16(%rdi, %rax), %rax
ret
.p2align 4
L(prolog_find_zero_in_first_wchar):
test $1, %eax
jz L(return_null)
lea -16(%rdi), %rax
ret
.p2align 4
L(prolog_find_zero_in_second_wchar):
and $1 << 5 - 1, %eax
jz L(return_null)
test $15 << 4, %al
jnz L(match_second_wchar)
lea -16(%rdi), %rax
ret
.p2align 4
L(prolog_find_zero_in_third_wchar):
and $1 << 9 - 1, %eax
jz L(return_null)
test %ah, %ah
jnz L(match_third_wchar)
test $15 << 4, %al
jnz L(match_second_wchar)
lea -16(%rdi), %rax
ret
.p2align 4
L(match_second_wchar):
lea -12(%rdi), %rax
ret
.p2align 4
L(match_third_wchar):
lea -8(%rdi), %rax
ret
.p2align 4
L(return_null):
xor %eax, %eax
ret
END (__wcsrchr_old_2)
|
