1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
|
/* ix87 specific implementation of arcsinh.
Copyright (C) 1996-1997, 1999, 2005, 2012 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <machine/asm.h>
.section .rodata
.align ALIGNARG(4)
ASM_TYPE_DIRECTIVE(huge,@object)
huge: .double 1e+36
ASM_SIZE_DIRECTIVE(huge)
ASM_TYPE_DIRECTIVE(one,@object)
one: .double 1.0
ASM_SIZE_DIRECTIVE(one)
ASM_TYPE_DIRECTIVE(limit,@object)
limit: .double 0.29
ASM_SIZE_DIRECTIVE(limit)
#ifdef PIC
#define MO(op) op##@GOTOFF(%edx)
#else
#define MO(op) op
#endif
.text
ENTRY(__asinhf)
movl 4(%esp), %ecx
movl $0x7fffffff, %eax
andl %ecx, %eax
andl $0x80000000, %ecx
movl %eax, %edx
orl $0x807fffff, %edx
incl %edx
jz 7f // x in ħInf or NaN
xorl %ecx, 4(%esp)
flds 4(%esp) // |x|
cmpl $0x38000000, %eax
jb 2f // |x| < 2^-14
fldln2 // log(2) : |x|
cmpl $0x47000000, %eax
fxch // |x| : log(2)
ja 3f // |x| > 2^14
#ifdef PIC
LOAD_PIC_REG (dx)
#endif
cmpl $0x40000000, %eax
ja 5f // |x| > 2
// 2^-14 <= |x| <= 2 => y = sign(x)*log1p(|x|+|x|^2/(1+sqrt(1+|x|^2)))
fld %st // |x| : |x| : log(2)
fmul %st(1) // |x|^2 : |x| : log(2)
fld %st // |x|^2 : |x|^2 : |x| : log(2)
faddl MO(one) // 1+|x|^2 : |x|^2 : |x| : log(2)
fsqrt // sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
faddl MO(one) // 1+sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
fdivrp // |x|^2/(1+sqrt(1+|x|^2)) : |x| : log(2)
faddp // |x|+|x|^2/(1+sqrt(1+|x|^2)) : log(2)
fcoml MO(limit)
fnstsw
sahf
ja 6f
fyl2xp1
jecxz 4f
fchs
4: ret
7: flds 4(%esp)
ret
6: faddl MO(one)
fyl2x
jecxz 4f
fchs
4: ret
// |x| < 2^-14 => y = x (inexact iff |x| != 0.0)
.align ALIGNARG(4)
2:
#ifdef PIC
LOAD_PIC_REG (dx)
#endif
jecxz 4f
fchs // x
4: fld %st // x : x
faddl MO(huge) // huge+x : x
fstp %st(0) // x
ret
// |x| > 2^14 => y = sign(x) * (log(|x|) + log(2))
.align ALIGNARG(4)
3: fyl2x // log(|x|)
fldln2 // log(2) : log(|x|)
faddp // log(|x|)+log(2)
jecxz 4f
fchs
4: ret
// |x| > 2 => y = sign(x) * log(2*|x| + 1/(|x|+sqrt(x*x+1)))
.align ALIGNARG(4)
5: fld %st // |x| : |x| : log(2)
fadd %st, %st(1) // |x| : 2*|x| : log(2)
fld %st // |x| : |x| : 2*|x| : log(2)
fmul %st(1) // |x|^2 : |x| : 2*|x| : log(2)
faddl MO(one) // 1+|x|^2 : |x| : 2*|x| : log(2)
fsqrt // sqrt(1+|x|^2) : |x| : 2*|x| : log(2)
faddp // |x|+sqrt(1+|x|^2) : 2*|x| : log(2)
fdivrl MO(one) // 1/(|x|+sqrt(1+|x|^2)) : 2*|x| : log(2)
faddp // 2*|x|+1/(|x|+sqrt(1+|x|^2)) : log(2)
fyl2x // log(2*|x|+1/(|x|+sqrt(1+|x|^2)))
jecxz 4f
fchs
4: ret
END(__asinhf)
weak_alias (__asinhf, asinhf)
|
