1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
|
/* Copyright (C) 2013 BMW Group
* Author: Manfred Bathelt (manfred.bathelt@bmw.de)
* Author: Juergen Gehring (juergen.gehring@bmw.de)
* This Source Code Form is subject to the terms of the Mozilla Public
* License, v. 2.0. If a copy of the MPL was not distributed with this
* file, You can obtain one at http://mozilla.org/MPL/2.0/. */
package org.genivi.commonapi.core.generator
import javax.inject.Inject
import org.eclipse.xtext.generator.IFileSystemAccess
import org.franca.core.franca.FAttribute
import org.franca.core.franca.FInterface
class FInterfaceStubGenerator {
@Inject private extension FTypeGenerator
@Inject private extension FrancaGeneratorExtensions
def generateStub(FInterface fInterface, IFileSystemAccess fileSystemAccess) {
fileSystemAccess.generateFile(fInterface.stubHeaderPath, fInterface.generateStubHeader)
fileSystemAccess.generateFile(fInterface.stubDefaultHeaderPath, fInterface.generateStubDefaultHeader)
fileSystemAccess.generateFile(fInterface.stubDefaultSourcePath, fInterface.generateStubDefaultSource)
}
def private generateStubHeader(FInterface fInterface) '''
«generateCommonApiLicenseHeader»
#ifndef «fInterface.defineName»_STUB_H_
#define «fInterface.defineName»_STUB_H_
«fInterface.generateRequiredTypeIncludes»
#include "«fInterface.name».h"
#include <CommonAPI/Stub.h>
«fInterface.model.generateNamespaceBeginDeclaration»
/**
* Receives messages from remote and handles all dispatching of deserialized calls
* to a stub for the service «fInterface.name». Also provides means to send broadcasts
* and attribute-changed-notifications of observable attributes as defined by this service.
* An application developer should not need to bother with this class.
*/
class «fInterface.stubAdapterClassName»: virtual public CommonAPI::StubAdapter, public «fInterface.name» {
public:
«FOR attribute : fInterface.attributes»
«IF attribute.isObservable»
///Notifies all remote listeners about a change of value of the attribute «attribute.name».
virtual void «attribute.stubAdapterClassFireChangedMethodName»(const «attribute.getTypeName(fInterface.model)»& «attribute.name») = 0;
«ENDIF»
«ENDFOR»
«FOR broadcast : fInterface.broadcasts»
/**
* Sends a broadcast event for «broadcast.name». Should not be called directly.
* Instead, the "fire<broadcastName>Event" methods of the stub should be used.
*/
virtual void «broadcast.stubAdapterClassFireEventMethodName»(«broadcast.outArgs.map['const ' + getTypeName(fInterface.model) + '& ' + name].join(', ')») = 0;
«ENDFOR»
};
/**
* Defines the necessary callbacks to handle remote set events related to the attributes
* defined in the IDL description for «fInterface.name».
* For each attribute two callbacks are defined:
* - a verification callback that allows to verify the requested value and to prevent setting
* e.g. an invalid value ("onRemoteSet<AttributeName>").
* - an action callback to do local work after the attribute value has been changed
* ("onRemote<AttributeName>Changed").
*
* This class and the one below are the ones an application developer needs to have
* a look at if he wants to implement a service.
*/
class «fInterface.stubRemoteEventClassName» {
public:
virtual ~«fInterface.stubRemoteEventClassName»() { }
«FOR attribute : fInterface.attributes»
/// Verification callback for remote set requests on the attribute «attribute.name».
virtual bool «attribute.stubRemoteEventClassSetMethodName»(«attribute.getTypeName(fInterface.model)» «attribute.name») = 0;
/// Action callback for remote set requests on the attribute «attribute.name».
virtual void «attribute.stubRemoteEventClassChangedMethodName»() = 0;
«ENDFOR»
};
/**
* Defines the interface that must be implemented by any class that should provide
* the service «fInterface.name» to remote clients.
* This class and the one above are the ones an application developer needs to have
* a look at if he wants to implement a service.
*/
class «fInterface.stubClassName» : public CommonAPI::Stub<«fInterface.stubAdapterClassName» , «fInterface.stubRemoteEventClassName»> {
public:
virtual ~«fInterface.stubClassName»() { }
«FOR attribute : fInterface.attributes»
/// Provides getter access to the attribute «attribute.name».
virtual const «attribute.getTypeName(fInterface.model)»& «attribute.stubClassGetMethodName»() = 0;
«ENDFOR»
«FOR method: fInterface.methods»
/// This is the method that will be called on remote calls on the method «method.name».
virtual void «method.name»(«method.generateStubSignature») = 0;
«ENDFOR»
«FOR broadcast : fInterface.broadcasts»
/// Sends a broadcast event for «broadcast.name».
virtual void «broadcast.stubAdapterClassFireEventMethodName»(«broadcast.outArgs.map['const ' + getTypeName(fInterface.model) + '& ' + name].join(', ')») = 0;
«ENDFOR»
};
«fInterface.model.generateNamespaceEndDeclaration»
#endif // «fInterface.defineName»_STUB_H_
'''
def private generateStubDefaultHeader(FInterface fInterface) '''
«generateCommonApiLicenseHeader»
#ifndef «fInterface.defineName»_STUB_DEFAULT_H_
#define «fInterface.defineName»_STUB_DEFAULT_H_
#include <«fInterface.stubHeaderPath»>
«fInterface.model.generateNamespaceBeginDeclaration»
/**
* Provides a default implementation for «fInterface.stubRemoteEventClassName» and
* «fInterface.stubClassName». Method callbacks have an empty implementation,
* remote set calls on attributes will always change the value of the attribute
* to the one received.
*
* Override this stub if you only want to provide a subset of the functionality
* that would be defined for this service, and/or if you do not need any non-default
* behaviour.
*/
class «fInterface.stubDefaultClassName» : public «fInterface.stubClassName» {
public:
«fInterface.stubDefaultClassName»();
«fInterface.stubRemoteEventClassName»* initStubAdapter(const std::shared_ptr<«fInterface.stubAdapterClassName»>& stubAdapter);
«FOR attribute : fInterface.attributes»
virtual const «attribute.getTypeName(fInterface.model)»& «attribute.stubClassGetMethodName»();
virtual void «attribute.stubDefaultClassSetMethodName»(«attribute.getTypeName(fInterface.model)» value);
«ENDFOR»
«FOR method: fInterface.methods»
virtual void «method.name»(«method.generateStubSignature»);
«ENDFOR»
«FOR broadcast : fInterface.broadcasts»
virtual void «broadcast.stubAdapterClassFireEventMethodName»(«broadcast.outArgs.map['const ' + getTypeName(fInterface.model) + '& ' + name].join(', ')»);
«ENDFOR»
protected:
«FOR attribute : fInterface.attributes»
virtual void «attribute.stubRemoteEventClassChangedMethodName»();
virtual bool «attribute.stubDefaultClassTrySetMethodName»(«attribute.getTypeName(fInterface.model)» value);
virtual bool «attribute.stubDefaultClassValidateMethodName»(const «attribute.getTypeName(fInterface.model)»& value);
«ENDFOR»
private:
class RemoteEventHandler: public «fInterface.stubRemoteEventClassName» {
public:
RemoteEventHandler(«fInterface.stubDefaultClassName»* defaultStub);
«FOR attribute : fInterface.attributes»
virtual bool «attribute.stubRemoteEventClassSetMethodName»(«attribute.getTypeName(fInterface.model)» value);
virtual void «attribute.stubRemoteEventClassChangedMethodName»();
«ENDFOR»
private:
«fInterface.stubDefaultClassName»* defaultStub_;
};
RemoteEventHandler remoteEventHandler_;
std::shared_ptr<«fInterface.stubAdapterClassName»> stubAdapter_;
«FOR attribute : fInterface.attributes»
«attribute.getTypeName(fInterface.model)» «attribute.stubDefaultClassVariableName»;
«ENDFOR»
};
«fInterface.model.generateNamespaceEndDeclaration»
#endif // «fInterface.defineName»_STUB_DEFAULT_H_
'''
def private generateStubDefaultSource(FInterface fInterface) '''
«generateCommonApiLicenseHeader»
#include <«fInterface.stubDefaultHeaderPath»>
«fInterface.model.generateNamespaceBeginDeclaration»
«fInterface.stubDefaultClassName»::«fInterface.stubDefaultClassName»():
remoteEventHandler_(this) {
}
«fInterface.stubRemoteEventClassName»* «fInterface.stubDefaultClassName»::initStubAdapter(const std::shared_ptr<«fInterface.stubAdapterClassName»>& stubAdapter) {
stubAdapter_ = stubAdapter;
return &remoteEventHandler_;
}
«FOR attribute : fInterface.attributes»
const «attribute.getTypeName(fInterface.model)»& «fInterface.stubDefaultClassName»::«attribute.stubClassGetMethodName»() {
return «attribute.stubDefaultClassVariableName»;
}
void «fInterface.stubDefaultClassName»::«attribute.stubDefaultClassSetMethodName»(«attribute.getTypeName(fInterface.model)» value) {
«IF attribute.isObservable»const bool valueChanged = «ENDIF»«attribute.stubDefaultClassTrySetMethodName»(std::move(value));
«IF attribute.isObservable»
if (valueChanged)
stubAdapter_->«attribute.stubAdapterClassFireChangedMethodName»(«attribute.stubDefaultClassVariableName»);
«ENDIF»
}
void «fInterface.stubDefaultClassName»::«attribute.stubRemoteEventClassChangedMethodName»() {
// No operation in default
}
bool «fInterface.stubDefaultClassName»::«attribute.stubDefaultClassTrySetMethodName»(«attribute.getTypeName(fInterface.model)» value) {
if (!«attribute.stubDefaultClassValidateMethodName»(value))
return false;
const bool valueChanged = («attribute.stubDefaultClassVariableName» != value);
«attribute.stubDefaultClassVariableName» = std::move(value);
return valueChanged;
}
bool «fInterface.stubDefaultClassName»::«attribute.stubDefaultClassValidateMethodName»(const «attribute.getTypeName(fInterface.model)»& value) {
return true;
}
bool «fInterface.stubDefaultClassName»::RemoteEventHandler::«attribute.stubRemoteEventClassSetMethodName»(«attribute.getTypeName(fInterface.model)» value) {
return defaultStub_->«attribute.stubDefaultClassTrySetMethodName»(std::move(value));
}
void «fInterface.stubDefaultClassName»::RemoteEventHandler::«attribute.stubRemoteEventClassChangedMethodName»() {
defaultStub_->«attribute.stubRemoteEventClassChangedMethodName»();
}
«ENDFOR»
«FOR method : fInterface.methods»
void «fInterface.stubDefaultClassName»::«method.name»(«method.generateStubSignature») {
// No operation in default
}
«ENDFOR»
«FOR broadcast : fInterface.broadcasts»
void «fInterface.stubDefaultClassName»::«broadcast.stubAdapterClassFireEventMethodName»(«broadcast.outArgs.map['const ' + getTypeName(fInterface.model) + '& ' + name].join(', ')») {
stubAdapter_->«broadcast.stubAdapterClassFireEventMethodName»(«broadcast.outArgs.map[name].join(', ')»);
}
«ENDFOR»
«fInterface.stubDefaultClassName»::RemoteEventHandler::RemoteEventHandler(«fInterface.stubDefaultClassName»* defaultStub):
defaultStub_(defaultStub) {
}
«fInterface.model.generateNamespaceEndDeclaration»
'''
def private getStubDefaultClassSetMethodName(FAttribute fAttribute) {
'set' + fAttribute.name.toFirstUpper + 'Attribute'
}
def private getStubDefaultClassTrySetMethodName(FAttribute fAttribute) {
'trySet' + fAttribute.name.toFirstUpper + 'Attribute'
}
def private getStubDefaultClassValidateMethodName(FAttribute fAttribute) {
'validate' + fAttribute.name.toFirstUpper + 'AttributeRequestedValue'
}
def private getStubDefaultClassVariableName(FAttribute fAttribute) {
fAttribute.name.toFirstLower + 'AttributeValue_'
}
}
|
