Makefile.in (NM_FOR_TARGET): New.

        * Makefile.in (NM_FOR_TARGET): New.
        (libgcc.mk): Pass SHLIB_MKMAP, SHLIB_MAPFILES.
        (libgcc.a, stmp-multilib): Pass NM_FOR_TARGET.
        * mklibgcc.in: If SHLIB_MKMAP, build libgcc.map.  Depend the
        shared library build on that and EXTRA_MULTILIB_PARTS.
        * mkmap-flat.awk: New file.
        * mkmap-symver.awk: New file.
        * libgcc-std.ver: New file.
        * config/libgcc-glibc.ver: New file.
        * config/ia64/libgcc-ia64.ver: New file.
        * config/t-linux (SHLIB_MKMAP, SHLIB_MAPFILES): New.
        (SHLIB_LINK): Add --version-script.
        * config/ia64/t-ia64 (SHLIB_MAPFILES): Add libgcc-ia64.ver.
        * config/mips/t-iris6 (SHLIB_MKMAP, SHLIB_MAPFILES): New.
        * config/sparc/t-sol2 (SHLIB_MKMAP, SHLIB_MAPFILES): New.
        (SHLIB_LINK): Add -M.

From-SVN: r36746

1 files changed, 78 insertions, 0 deletions

diff --git a/gcc/mkmap-flat.awk b/gcc/mkmap-flat.awk
new file mode 100644
index 00000000000..de22d7c33e1
--- /dev/null
+++ b/gcc/mkmap-flat.awk
@@ -0,0 +1,78 @@
+# Generate a flat list of symbols to export.
+#	Contributed by Richard Henderson <rth@cygnus.com>
+#
+# This file is part of GNU CC.
+#
+# GNU CC is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2, or (at your option)
+# any later version.
+#
+# GNU CC is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with GNU CC; see the file COPYING.  If not, write to
+# the Free Software Foundation, 59 Temple Place - Suite 330,
+# Boston MA 02111-1307, USA.
+
+BEGIN {
+  state = "nm";
+}
+
+# Remove comment and blank lines.
+/^ *#/ || /^ *$/ {
+  next;
+}
+
+# We begin with nm input.  Collect the set of symbols that are present
+# so that we can elide undefined symbols.
+
+state == "nm" && /^%%/ {
+  state = "ver";
+  next;
+}
+
+state == "nm" && ($1 == "U" || $2 == "U") {
+  next;
+}
+
+state == "nm" && NF == 3 {
+  def[$3] = 1;
+  next;
+}
+
+state == "nm" {
+  next;
+}
+
+# Now we process a simplified variant of the Solaris symbol version
+# script.  We have one symbol per line, no semicolons, simple markers
+# for beginning and ending each section, and %inherit markers for
+# describing version inheritence.  A symbol may appear in more than
+# one symbol version, and the last seen takes effect.
+
+NF == 3 && $1 == "%inherit" {
+  next;
+}
+
+NF == 2 && $2 == "{" {
+  next;
+}
+
+$1 == "}" {
+  next;
+}
+
+{
+  export[$1] = 1;
+  next;
+}
+
+END {
+  for (sym in export)
+    if (def[sym])
+      print sym;
+}