Renaming of target specific files for clarity

        * Makefile.in: Rename GNAT target specific files.

	* 31soccon.ads, 31soliop.ads 35soccon.ads, 3asoccon.ads,
	3bsoccon.ads, 3gsoccon.ads, 3hsoccon.ads, 3psoccon.ads,
	3ssoccon.ads, 3ssoliop.ads, 3veacodu.adb, 3vexpect.adb,
	3vsoccon.ads, 3vsocthi.adb, 3vsocthi.ads, 3vtrasym.adb,
	3wsoccon.ads, 3wsocthi.adb, 3wsocthi.ads, 3wsoliop.ads,
	3zsoccon.ads, 3zsocthi.adb, 3zsocthi.ads, 41intnam.ads,
	42intnam.ads, 45intnam.ads, 4aintnam.ads, 4cintnam.ads,
	4gintnam.ads, 4hexcpol.adb, 4hintnam.ads, 4lintnam.ads,
	4nintnam.ads, 4ointnam.ads, 4onumaux.ads, 4pintnam.ads,
	4sintnam.ads, 4vcaldel.adb, 4vcalend.adb, 4vcalend.ads,
	4vintnam.ads, 4wcalend.adb, 4wexcpol.adb, 4wintnam.ads,
	4zintnam.ads, 4znumaux.ads, 4zsytaco.adb, 4zsytaco.ads,
	51osinte.adb, 51osinte.ads, 51system.ads,
	52osinte.adb, 52osinte.ads, 53osinte.ads, 54osinte.ads,
	55osinte.adb, 55osinte.ads, 55system.ads, 56osinte.adb,
	56osinte.ads, 56system.ads, 56taprop.adb, 56taspri.ads,
	56tpopsp.adb, 57system.ads, 58system.ads,
	5amastop.adb, 5aml-tgt.adb, 5aosinte.adb, 5aosinte.ads,
	5asystem.ads, 5ataprop.adb, 5atasinf.ads, 5ataspri.ads,
	5atpopsp.adb, 5avxwork.ads, 5bml-tgt.adb, 5bosinte.adb,
	5bosinte.ads, 5bsystem.ads, 5cosinte.ads, 5csystem.ads,
	5dsystem.ads, 5esystem.ads, 5fintman.adb, 5fosinte.adb,
	5fosinte.ads, 5fsystem.ads, 5ftaprop.adb, 5ftasinf.ads,
	5ginterr.adb, 5gintman.adb, 5gmastop.adb, 5gml-tgt.adb,
	5gosinte.ads, 5gproinf.adb, 5gproinf.ads, 5gsystem.ads,
	5gtaprop.adb, 5gtasinf.adb, 5gtasinf.ads, 5gtpgetc.adb,
	5hml-tgt.adb, 5hosinte.adb, 5hosinte.ads, 5hparame.ads,
	5hsystem.ads, 5htaprop.adb, 5htaspri.ads, 5htraceb.adb,
	5iosinte.adb, 5iosinte.ads, 5itaprop.adb, 5itaspri.ads,
	5ksystem.ads, 5kvxwork.ads, 5lml-tgt.adb, 5losinte.ads,
	5lparame.adb, 5lsystem.ads, 5msystem.ads, 5mvxwork.ads,
	5ninmaop.adb, 5nintman.adb, 5nosinte.ads, 5nsystem.ads,
	5ntaprop.adb, 5ntaspri.ads, 5ointerr.adb, 5omastop.adb,
	5oosinte.adb, 5oosinte.ads, 5oosprim.adb, 5oparame.adb,
	5osystem.ads, 5otaprop.adb, 5otaspri.ads, 5posinte.ads,
	5posprim.adb, 5psystem.ads, 5pvxwork.ads, 5sintman.adb,
	5sml-tgt.adb, 5sosinte.adb, 5sosinte.ads, 5sosprim.adb,
	5sparame.adb, 5ssystem.ads, 5staprop.adb, 5stasinf.adb,
	5stasinf.ads, 5staspri.ads, 5stpopsp.adb, 5svxwork.ads,
	5tosinte.ads, 5usystem.ads, 5vasthan.adb, 5vdirval.adb,
	5vinmaop.adb, 5vinterr.adb, 5vintman.adb, 5vintman.ads,
	5vmastop.adb, 5vml-tgt.adb, 5vosinte.adb, 5vosinte.ads,
	5vosprim.adb, 5vosprim.ads, 5vparame.ads, 5vsymbol.adb,
	5vsystem.ads, 5vtaprop.adb, 5vtaspri.ads, 5vtpopde.adb,
	5vtpopde.ads, 5vtraent.adb, 5vtraent.ads, 5vvaflop.adb,
	5wdirval.adb, 5wgloloc.adb, 5wintman.adb, 5wmemory.adb,
	5wml-tgt.adb, 5wosinte.ads, 5wosprim.adb, 5wsystem.ads,
	5wtaprop.adb, 5wtaspri.ads, 5xparame.ads, 5xsystem.ads,
	5xvxwork.ads, 5yparame.ads, 5ysystem.ads, 5zinterr.adb,
	5zintman.adb, 5zintman.ads, 5zml-tgt.adb, 5zosinte.adb,
	5zosinte.ads, 5zosprim.adb, 5zparame.ads, 5zstchop.adb,
	5zsystem.ads, 5ztaprop.adb, 5ztaspri.ads, 5ztfsetr.adb,
	5ztpopsp.adb, 6vcpp.adb, 6vcstrea.adb, 6vinterf.ads,
	7sinmaop.adb, 7sintman.adb, 7sosinte.adb, 7sosprim.adb,
	7staprop.adb, 7staspri.ads, 7stfsetr.adb, 7stpopsp.adb,
	7straceb.adb, 7straces.adb, 7strafor.adb, 7strafor.ads,
	7stratas.adb, 86numaux.adb, 86numaux.ads: Replaced by files below.

	* a-caldel-vms.adb, a-calend-mingw.adb, a-calend-vms.adb,
	a-calend-vms.ads, a-dirval-mingw.adb, a-dirval-vms.adb,
	a-excpol-abort.adb, a-excpol-interix.adb, a-intnam-aix.ads,
	a-intnam-dummy.ads, a-intnam-freebsd.ads, a-intnam-hpux.ads,
	a-intnam-interix.ads, a-intnam-irix.ads, a-intnam-linux.ads,
	a-intnam-lynxos.ads, a-intnam-mingw.ads, a-intnam-os2.ads,
	a-intnam-solaris.ads, a-intnam-tru64.ads, a-intnam-unixware.ads,
	a-intnam-vms.ads, a-intnam-vxworks.ads, a-numaux-libc-x86.ads,
	a-numaux-vxworks.ads, a-numaux-x86.adb, a-numaux-x86.ads,
	a-sytaco-vxworks.adb, a-sytaco-vxworks.ads, g-eacodu-vms.adb,
	g-expect-vms.adb, g-soccon-aix.ads, g-soccon-freebsd.ads,
	g-soccon-hpux.ads, g-soccon-interix.ads, g-soccon-irix.ads,
	g-soccon-mingw.ads, g-soccon-solaris.ads, g-soccon-tru64.ads,
	g-soccon-unixware.ads, g-soccon-vms.adb, g-soccon-vxworks.ads,
	g-socthi-mingw.adb, g-socthi-mingw.ads, g-socthi-vms.adb,
	g-socthi-vms.ads, g-socthi-vxworks.adb, g-socthi-vxworks.ads,
	g-soliop-mingw.ads, g-soliop-solaris.ads, g-soliop-unixware.ads,
	g-trasym-vms.adb, i-cpp-vms.adb, i-cstrea-vms.adb,
	interfac-vms.ads, mlib-tgt-aix.adb, mlib-tgt-hpux.adb,
	mlib-tgt-irix.adb, mlib-tgt-linux.adb, mlib-tgt-mingw.adb,
	mlib-tgt-solaris.adb, mlib-tgt-tru64.adb, mlib-tgt-vms.adb,
	mlib-tgt-vxworks.adb, s-asthan-vms.adb, s-gloloc-mingw.adb,
	s-inmaop-dummy.adb, s-inmaop-posix.adb, s-inmaop-vms.adb,
	s-interr-dummy.adb, s-interr-sigaction.adb, s-interr-vms.adb,
	s-interr-vxworks.adb, s-intman-dummy.adb, s-intman-irix.adb,
	s-intman-irix-athread.adb, s-intman-mingw.adb, s-intman-posix.adb,
	s-intman-solaris.adb, s-intman-vms.adb, s-intman-vms.ads,
	s-intman-vxworks.adb, s-intman-vxworks.ads, s-mastop-irix.adb,
	s-mastop-tru64.adb, s-mastop-vms.adb, s-mastop-x86.adb,
	s-memory-mingw.adb, s-osinte-aix.adb, s-osinte-aix.ads,
	s-osinte-aix-fsu.ads, s-osinte-dummy.ads, s-osinte-freebsd.adb,
	s-osinte-freebsd.ads, s-osinte-fsu.adb, s-osinte-hpux.ads,
	s-osinte-hpux-dce.adb, s-osinte-hpux-dce.ads, s-osinte-interix.ads,
	s-osinte-irix.adb, s-osinte-irix.ads, s-osinte-irix-athread.ads,
	s-osinte-linux.ads, s-osinte-linux-fsu.ads, s-osinte-linux-ia64.ads,
	s-osinte-lynxos-3.adb, s-osinte-lynxos-3.ads, s-osinte-lynxos.adb,
	s-osinte-lynxos.ads, s-osinte-mingw.ads, s-osinte-os2.adb,
	s-osinte-os2.ads, s-osinte-posix.adb, s-osinte-solaris.adb,
	s-osinte-solaris.ads, s-osinte-solaris-fsu.ads,
	s-osinte-solaris-posix.ads, s-osinte-tru64.adb, s-osinte-tru64.ads,
	s-osinte-unixware.adb, s-osinte-unixware.ads, s-osinte-vms.adb,
	s-osinte-vms.ads, s-osinte-vxworks.adb,
	s-osinte-vxworks.ads, s-osprim-mingw.adb,
	s-osprim-os2.adb, s-osprim-posix.adb, s-osprim-solaris.adb,
	s-osprim-unix.adb, s-osprim-vms.adb, s-osprim-vms.ads,
	s-osprim-vxworks.adb, s-parame-ae653.ads, s-parame-hpux.ads,
	s-parame-linux.adb, s-parame-os2.adb, s-parame-solaris.adb,
	s-parame-vms.ads, s-parame-vms-restrict.ads, s-parame-vxworks.ads,
	s-proinf-irix-athread.adb, s-proinf-irix-athread.ads,
	s-stchop-vxworks.adb, s-taprop-dummy.adb,
	s-taprop-hpux-dce.adb, s-taprop-irix.adb,
	s-taprop-irix-athread.adb, s-taprop-linux.adb, s-taprop-lynxos.adb,
	s-taprop-mingw.adb, s-taprop-os2.adb, s-taprop-posix.adb,
	s-taprop-solaris.adb, s-taprop-tru64.adb, s-taprop-vms.adb,
	s-taprop-vxworks.adb, s-tasinf-irix.ads, s-tasinf-irix-athread.adb,
	s-tasinf-irix-athread.ads, s-tasinf-solaris.adb, s-tasinf-solaris.ads,
	s-tasinf-tru64.ads, s-taspri-dummy.ads, s-taspri-hpux-dce.ads,
	s-taspri-linux.ads, s-taspri-lynxos.ads, s-taspri-mingw.ads,
	s-taspri-os2.ads, s-taspri-posix.ads, s-taspri-solaris.ads,
	s-taspri-tru64.ads, s-taspri-vms.ads, s-taspri-vxworks.ads,
	s-tfsetr-default.adb, s-tfsetr-vxworks.adb, s-tpopde-vms.adb,
	s-tpopde-vms.ads, s-tpopsp-lynxos.adb, s-tpopsp-posix.adb,
	s-tpopsp-posix-foreign.adb, s-tpopsp-solaris.adb, s-tpopsp-vxworks.adb,
	s-traceb-hpux.adb, s-traceb-mastop.adb, s-traces-default.adb,
	s-traent-vms.adb, s-traent-vms.ads, s-trafor-default.adb,
	s-trafor-default.ads, s-tratas-default.adb, s-vaflop-vms.adb,
	s-vxwork-alpha.ads, s-vxwork-m68k.ads, s-vxwork-mips.ads,
	s-vxwork-ppc.ads, s-vxwork-sparcv9.ads, s-vxwork-xscale.ads,
	symbols-vms.adb, system-aix.ads, system-freebsd-x86.ads,
	system-hpux.ads, system-interix.ads, system-irix-n32.ads,
	system-irix-o32.ads, system-linux-x86_64.ads,
	system-linux-x86.ads, system-lynxos-ppc.ads, system-lynxos-x86.ads,
	system-mingw.ads, system-os2.ads, system-solaris-sparc.ads,
	system-solaris-sparcv9.ads, system-solaris-x86.ads, system-tru64.ads,
	system-unixware.ads, system-vms.ads, system-vms-zcx.ads,
	system-vxworks-alpha.ads, system-vxworks-m68k.ads,
	system-vxworks-mips.ads, system-vxworks-ppc.ads,
	system-vxworks-sparcv9.ads, system-vxworks-xscale.ads: Replace files
	above.


git-svn-id: svn+ssh://gcc.gnu.org/svn/gcc/trunk@81834 138bc75d-0d04-0410-961f-82ee72b054a4

1 files changed, 286 insertions, 0 deletions

diff --git a/gcc/ada/s-osprim-mingw.adb b/gcc/ada/s-osprim-mingw.adb
new file mode 100644
index 00000000000..07a8ca79eab
--- /dev/null
+++ b/gcc/ada/s-osprim-mingw.adb
@@ -0,0 +1,286 @@
+------------------------------------------------------------------------------
+--                                                                          --
+--                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
+--                                                                          --
+--                  S Y S T E M . O S _ P R I M I T I V E S                 --
+--                                                                          --
+--                                  B o d y                                 --
+--                                                                          --
+--          Copyright (C) 1998-2003 Free Software Foundation, Inc.          --
+--                                                                          --
+-- GNARL is free software; you can  redistribute it  and/or modify it under --
+-- terms of the  GNU General Public License as published  by the Free Soft- --
+-- ware  Foundation;  either version 2,  or (at your option) any later ver- --
+-- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
+-- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
+-- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
+-- for  more details.  You should have  received  a copy of the GNU General --
+-- Public License  distributed with GNARL; see file COPYING.  If not, write --
+-- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
+-- MA 02111-1307, USA.                                                      --
+--                                                                          --
+-- As a special exception,  if other files  instantiate  generics from this --
+-- unit, or you link  this unit with other files  to produce an executable, --
+-- this  unit  does not  by itself cause  the resulting  executable  to  be --
+-- covered  by the  GNU  General  Public  License.  This exception does not --
+-- however invalidate  any other reasons why  the executable file  might be --
+-- covered by the  GNU Public License.                                      --
+--                                                                          --
+-- GNARL was developed by the GNARL team at Florida State University.       --
+-- Extensive contributions were provided by Ada Core Technologies, Inc.     --
+--                                                                          --
+------------------------------------------------------------------------------
+
+--  This is the NT version of this package
+
+with Ada.Exceptions;
+with Interfaces.C;
+
+package body System.OS_Primitives is
+
+   ---------------------------
+   -- Win32 API Definitions --
+   ---------------------------
+
+   --  These definitions are copied from System.OS_Interface because we do not
+   --  want to depend on gnarl here.
+
+   type DWORD is new Interfaces.C.unsigned_long;
+
+   type LARGE_INTEGER is delta 1.0 range -2.0**63 .. 2.0**63 - 1.0;
+
+   type BOOL is new Boolean;
+   for BOOL'Size use Interfaces.C.unsigned_long'Size;
+
+   procedure GetSystemTimeAsFileTime (lpFileTime : access Long_Long_Integer);
+   pragma Import (Stdcall, GetSystemTimeAsFileTime, "GetSystemTimeAsFileTime");
+
+   function QueryPerformanceCounter
+     (lpPerformanceCount : access LARGE_INTEGER) return BOOL;
+   pragma Import
+     (Stdcall, QueryPerformanceCounter, "QueryPerformanceCounter");
+
+   function QueryPerformanceFrequency
+     (lpFrequency : access LARGE_INTEGER) return BOOL;
+   pragma Import
+     (Stdcall, QueryPerformanceFrequency, "QueryPerformanceFrequency");
+
+   procedure Sleep (dwMilliseconds : DWORD);
+   pragma Import (Stdcall, Sleep, External_Name => "Sleep");
+
+   ----------------------------------------
+   -- Data for the high resolution clock --
+   ----------------------------------------
+
+   --  Declare some pointers to access multi-word data above. This is needed
+   --  to workaround a limitation in the GNU/Linker auto-import feature used
+   --  to build the GNAT runtime DLLs. In fact the Clock and Monotonic_Clock
+   --  routines are inlined and they are using some multi-word variables.
+   --  GNU/Linker will fail to auto-import those variables when building
+   --  libgnarl.dll. The indirection level introduced here has no measurable
+   --  penalties.
+   --
+   --  Note that access variables below must not be declared as constant
+   --  otherwise the compiler optimization will remove this indirect access.
+
+   type DA is access all Duration;
+   --  Use to have indirect access to multi-word variables
+
+   type LIA is access all LARGE_INTEGER;
+   --  Use to have indirect access to multi-word variables
+
+   type LLIA is access all Long_Long_Integer;
+   --  Use to have indirect access to multi-word variables
+
+   Tick_Frequency : aliased LARGE_INTEGER;
+   TFA : constant LIA := Tick_Frequency'Access;
+   --  Holds frequency of high-performance counter used by Clock
+   --  Windows NT uses a 1_193_182 Hz counter on PCs.
+
+   Base_Ticks : aliased LARGE_INTEGER;
+   BTA : constant LIA := Base_Ticks'Access;
+   --  Holds the Tick count for the base time.
+
+   Base_Monotonic_Ticks : aliased LARGE_INTEGER;
+   BMTA : constant LIA := Base_Monotonic_Ticks'Access;
+   --  Holds the Tick count for the base monotonic time
+
+   Base_Clock : aliased Duration;
+   BCA : constant DA := Base_Clock'Access;
+   --  Holds the current clock for the standard clock's base time
+
+   Base_Monotonic_Clock : aliased Duration;
+   BMCA : constant DA := Base_Monotonic_Clock'Access;
+   --  Holds the current clock for monotonic clock's base time
+
+   Base_Time : aliased Long_Long_Integer;
+   BTiA : constant LLIA := Base_Time'Access;
+   --  Holds the base time used to check for system time change, used with
+   --  the standard clock.
+
+   procedure Get_Base_Time;
+   --  Retrieve the base time and base ticks. These values will be used by
+   --  clock to compute the current time by adding to it a fraction of the
+   --  performance counter. This is for the implementation of a
+   --  high-resolution clock. Note that this routine does not change the base
+   --  monotonic values used by the monotonic clock.
+
+   -----------
+   -- Clock --
+   -----------
+
+   --  This implementation of clock provides high resolution timer values
+   --  using QueryPerformanceCounter. This call return a 64 bits values (based
+   --  on the 8253 16 bits counter). This counter is updated every 1/1_193_182
+   --  times per seconds. The call to QueryPerformanceCounter takes 6
+   --  microsecs to complete.
+
+   function Clock return Duration is
+      Max_Shift            : constant Duration        := 2.0;
+      Hundreds_Nano_In_Sec : constant Long_Long_Float := 1.0E7;
+      Current_Ticks        : aliased LARGE_INTEGER;
+      Elap_Secs_Tick       : Duration;
+      Elap_Secs_Sys        : Duration;
+      Now                  : aliased Long_Long_Integer;
+
+   begin
+      if not QueryPerformanceCounter (Current_Ticks'Access) then
+         return 0.0;
+      end if;
+
+      GetSystemTimeAsFileTime (Now'Access);
+
+      Elap_Secs_Sys :=
+        Duration (Long_Long_Float (abs (Now - BTiA.all)) /
+                    Hundreds_Nano_In_Sec);
+
+      Elap_Secs_Tick :=
+        Duration (Long_Long_Float (Current_Ticks - BTA.all) /
+                  Long_Long_Float (TFA.all));
+
+      --  If we have a shift of more than Max_Shift seconds we resynchonize the
+      --  Clock. This is probably due to a manual Clock adjustment, an DST
+      --  adjustment or an NTP synchronisation. And we want to adjust the
+      --  time for this system (non-monotonic) clock.
+
+      if abs (Elap_Secs_Sys - Elap_Secs_Tick) > Max_Shift then
+         Get_Base_Time;
+
+         Elap_Secs_Tick :=
+           Duration (Long_Long_Float (Current_Ticks - BTA.all) /
+                     Long_Long_Float (TFA.all));
+      end if;
+
+      return BCA.all + Elap_Secs_Tick;
+   end Clock;
+
+   -------------------
+   -- Get_Base_Time --
+   -------------------
+
+   procedure Get_Base_Time is
+      --  The resolution for GetSystemTime is 1 millisecond.
+
+      --  The time to get both base times should take less than 1 millisecond.
+      --  Therefore, the elapsed time reported by GetSystemTime between both
+      --  actions should be null.
+
+      Max_Elapsed    : constant := 0;
+
+      Test_Now       : aliased Long_Long_Integer;
+
+      epoch_1970     : constant := 16#19D_B1DE_D53E_8000#; -- win32 UTC epoch
+      system_time_ns : constant := 100;                    -- 100 ns per tick
+      Sec_Unit       : constant := 10#1#E9;
+
+   begin
+      --  Here we must be sure that both of these calls are done in a short
+      --  amount of time. Both are base time and should in theory be taken
+      --  at the very same time.
+
+      loop
+         GetSystemTimeAsFileTime (Base_Time'Access);
+
+         if not QueryPerformanceCounter (Base_Ticks'Access) then
+            pragma Assert
+              (Standard.False,
+               "Could not query high performance counter in Clock");
+            null;
+         end if;
+
+         GetSystemTimeAsFileTime (Test_Now'Access);
+
+         exit when Test_Now - Base_Time = Max_Elapsed;
+      end loop;
+
+      Base_Clock := Duration
+        (Long_Long_Float ((Base_Time - epoch_1970) * system_time_ns) /
+         Long_Long_Float (Sec_Unit));
+   end Get_Base_Time;
+
+   ---------------------
+   -- Monotonic_Clock --
+   ---------------------
+
+   function Monotonic_Clock return Duration is
+      Current_Ticks  : aliased LARGE_INTEGER;
+      Elap_Secs_Tick : Duration;
+   begin
+      if not QueryPerformanceCounter (Current_Ticks'Access) then
+         return 0.0;
+      end if;
+
+      Elap_Secs_Tick :=
+        Duration (Long_Long_Float (Current_Ticks - BMTA.all) /
+                  Long_Long_Float (TFA.all));
+
+      return BMCA.all + Elap_Secs_Tick;
+   end Monotonic_Clock;
+
+   -----------------
+   -- Timed_Delay --
+   -----------------
+
+   procedure Timed_Delay (Time : Duration; Mode : Integer) is
+      Rel_Time   : Duration;
+      Abs_Time   : Duration;
+      Check_Time : Duration := Monotonic_Clock;
+
+   begin
+      if Mode = Relative then
+         Rel_Time := Time;
+         Abs_Time := Time + Check_Time;
+      else
+         Rel_Time := Time - Check_Time;
+         Abs_Time := Time;
+      end if;
+
+      if Rel_Time > 0.0 then
+         loop
+            Sleep (DWORD (Rel_Time * 1000.0));
+            Check_Time := Monotonic_Clock;
+
+            exit when Abs_Time <= Check_Time;
+
+            Rel_Time := Abs_Time - Check_Time;
+         end loop;
+      end if;
+   end Timed_Delay;
+
+--  Package elaboration, get starting time as base
+
+begin
+   if not QueryPerformanceFrequency (Tick_Frequency'Access) then
+      Ada.Exceptions.Raise_Exception
+        (Program_Error'Identity,
+         "cannot get high performance counter frequency");
+   end if;
+
+   Get_Base_Time;
+
+   --  Keep base clock and ticks for the monotonic clock. These values should
+   --  never be changed to ensure proper behavior of the monotonic clock.
+
+   Base_Monotonic_Clock := Base_Clock;
+   Base_Monotonic_Ticks := Base_Ticks;
+end System.OS_Primitives;