Made fixincludes a toplevel build module.

toplevel:
2004-08-31  Paolo Bonzini  <bonzini@gnu.org>

	* Makefile.def (build_modules): Add fixincludes.
	(dependencies): Make gcc depend on fixincludes.
	* configure.in (build_tools): Add fixincludes.
	(build_configdirs): Always include build_libs.
	* Makefile.in: Regenerate.
	* configure: Regenerate.

contrib:
2004-08-04  Paolo Bonzini  <bonzini@gnu.org>

	* gcc_update: Add fixincludes.

fixincludes:
2004-08-31  Paolo Bonzini  <bonzini@gnu.org>

	* .cvsignore: New.
	* Makefile.in: From gcc/fixinc/Makefile.in, making it fully
	autoconfiscated.
	* configure.ac: New.
	* config.h.in: Generate.
	* configure: Generate.
	* aclocal.m4: New.
	* fixlib.h: Remove inclusions of gcc files.
	* system.h: New.

	Other files copied from gcc/fixinc.

gcc:
2004-08-31  Paolo Bonzini  <bonzini@gnu.org>

	* Makefile.in (build_subdir): New substitution.
	(fixinc.sh): Simplify heavily since fixincludes is already built.
	(stmp-fixinc): Depend on specs.ready.
	(install-mkheaders): Use new location of fixincludes.
	(clean): Do not descend into fixinc.
	(FORBUILD): Replace with ../$(build_subdir).
	* configure.ac (build_subdir): Substitute.
	(FORBUILD): Do not set.
	(all_outputs): Remove fixinc/Makefile.
	(default commands): Do not create links in fixinc.
	* mkfixinc.sh: New, from fixinc/mkfixinc.sh without
	the fixincludes configuration steps and substituting
	@FIXINCL@ in fixinc.in.
	* fixinc.in: New, from fixinc/fixincl.sh.

	* fixinc/*: Removed.


git-svn-id: svn+ssh://gcc.gnu.org/svn/gcc/trunk@86824 138bc75d-0d04-0410-961f-82ee72b054a4

1 files changed, 62 insertions, 0 deletions

diff --git a/fixincludes/configure.ac b/fixincludes/configure.ac
new file mode 100644
index 00000000000..e0058b11640
--- /dev/null
+++ b/fixincludes/configure.ac
@@ -0,0 +1,62 @@
+AC_PREREQ(2.59)
+
+AC_INIT(fixincludes, [ ])
+AC_CONFIG_SRCDIR(inclhack.def)
+AC_CONFIG_AUX_DIR(..)
+AC_CANONICAL_SYSTEM
+AC_PROG_CC
+
+# Choose one or two-process fix methodology.  Systems that cannot handle
+# bi-directional pipes must use the two process method.
+#
+case $host in
+	i?86-*-msdosdjgpp* | \
+	*-*-beos* )
+		TARGET=twoprocess
+		AC_DEFINE(SEPARATE_FIX_PROC, 1, [Define if testing and fixing are done by separate process])
+		;;
+
+	vax-dec-bsd* )
+		TARGET=oneprocess
+		AC_DEFINE(exit, xexit, [Define to xexit if the host system does not support atexit])
+		AC_DEFINE(atexit, xatexit, [Define to xatexit if the host system does not support atexit])
+		;;
+
+	* )
+		TARGET=oneprocess
+		;;
+esac
+AC_SUBST(TARGET)
+
+# Checks for header files.
+AC_HEADER_STDC
+AC_CHECK_HEADERS([stddef.h stdlib.h strings.h unistd.h fcntl.h sys/file.h \
+	sys/stat.h])
+AC_CHECK_FUNCS(putc_unlocked fputc_unlocked fputs_unlocked \
+        fwrite_unlocked fprintf_unlocked)
+AC_CHECK_DECLS([abort, errno, putc_unlocked, fputc_unlocked,
+        fputs_unlocked, fwrite_unlocked, fprintf_unlocked])
+
+# Checks for typedefs, structures, and compiler characteristics.
+AC_C_CONST
+
+# Checks for library functions.
+gcc_AC_FUNC_MMAP_BLACKLIST
+
+AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
+AC_ARG_ENABLE(maintainer-mode,
+[  --enable-maintainer-mode enable make rules and dependencies not useful
+                          (and sometimes confusing) to the casual installer],
+      USE_MAINTAINER_MODE=$enableval,
+      USE_MAINTAINER_MODE=no)
+AC_MSG_RESULT($USE_MAINTAINER_MODE)
+if test "$USE_MAINTAINER_MODE" = yes; then
+  MAINT=
+else
+  MAINT='#'
+fi	
+AC_SUBST(MAINT)
+
+AC_CONFIG_HEADERS(config.h, [echo timestamp > stamp-h])
+AC_CONFIG_FILES(Makefile)
+AC_OUTPUT