blob: 766168a80477cf8bd04f1ef95dc6f33a9a660e53 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
|
;;; pcmpl-ack.el --- completion for ack tool
;; Copyright (C) 2012, 2013 Free Software Foundation, Inc.
;; Author: Leo Liu <sdl.web@gmail.com>
;; Keywords: tools, processes, convenience
;; Created: 2012-09-26
;; URL: https://github.com/leoliu/ack-el
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;; Provide pcompletion support for the cli tool `ack' which can be
;; downloaded from http://betterthangrep.com.
;;
;; Install:
;; (autoload 'pcomplete/ack "pcmpl-ack")
;;
;; Usage:
;; - To complete short options type '-' first
;; - To complete long options type '--' first
;; - Color name completion is supported following
;; --color-filename=, --color-match= and --color-lineno=
;; - Type completion is supported following --type=
;;; Code:
(require 'pcomplete)
(defcustom pcmpl-ack-program
(file-name-nondirectory (or (executable-find "ack-grep")
(executable-find "ack")
"ack"))
"Name of the ack program."
:type 'file
:group 'pcomplete)
(defvar pcmpl-ack-color-options
'("clear"
"reset"
"dark"
"bold"
"underline"
"underscore"
"blink"
"reverse"
"concealed"
"black"
"red"
"green"
"yellow"
"blue"
"magenta"
"on_black"
"on_red"
"on_green"
"on_yellow"
"on_blue"
"on_magenta"
"on_cyan"
"on_white")
"Color names for the `ack' command.")
(defun pcmpl-ack-run (buffer &rest args)
"Run ack with ARGS and send the output to BUFFER."
(condition-case nil
(apply 'call-process (or pcmpl-ack-program "ack") nil buffer nil args)
(file-error -1)))
(defun pcmpl-ack-short-options ()
"Short options for the `ack' command."
(with-temp-buffer
(let (options)
(when (zerop (pcmpl-ack-run t "--help"))
(goto-char (point-min))
(while (re-search-forward "^ -\\([^-]\\)" nil t)
(push (match-string 1) options))
(mapconcat 'identity (nreverse options) "")))))
(defun pcmpl-ack-long-options (&optional arg)
"Long options for the `ack' command."
(with-temp-buffer
(let (options)
(when (zerop (pcmpl-ack-run t (or arg "--help")))
(goto-char (point-min))
(while (re-search-forward
"\\(?: ?\\|, \\)\\(--\\(\\[no\\]\\)?\\([[:alnum:]-]+=?\\)\\)"
nil t)
(if (not (match-string 2))
(push (match-string 1) options)
(push (concat "--" (match-string 3)) options)
(push (concat "--no" (match-string 3)) options)))
(nreverse options)))))
(defun pcmpl-ack-type-options ()
"A list of types for the `ack' command."
(pcmpl-ack-long-options "--help-types"))
;;;###autoload
(defun pcomplete/ack ()
"Completion for the `ack' command.
Start an argument with '-' to complete short options and '--' for
long options."
;; No space after =
(while t
(if (pcomplete-match "^-" 0)
(cond
((pcomplete-match "^--color-\\w+=\\(\\S-*\\)" 0)
(pcomplete-here* pcmpl-ack-color-options
(pcomplete-match-string 1 0) t))
((pcomplete-match "^--\\(?:no\\)?ignore-dir=\\(\\S-*\\)" 0)
(pcomplete-here* (pcomplete-dirs)
(pcomplete-match-string 1 0) t))
((pcomplete-match "^--type=\\(\\S-*\\)" 0)
(pcomplete-here* (mapcar (lambda (type-option)
(substring type-option 2))
(pcmpl-ack-type-options))
(pcomplete-match-string 1 0) t))
((pcomplete-match "^--" 0)
(pcomplete-here* (append (pcmpl-ack-long-options)
(pcmpl-ack-type-options))))
(t (pcomplete-opt (pcmpl-ack-short-options))))
(pcomplete-here* (pcomplete-dirs-or-entries)))))
;;;###autoload
(defalias 'pcomplete/ack-grep 'pcomplete/ack)
(provide 'pcmpl-ack)
;;; pcmpl-ack.el ends here
|
