(make-temp-file): New function.

1 files changed, 24 insertions, 0 deletions

diff --git a/lisp/subr.el b/lisp/subr.el
index 7f145861ab3..8ade8bc85de 100644
--- a/lisp/subr.el
+++ b/lisp/subr.el
@@ -1302,4 +1302,28 @@ Return the modified alist."
       (setq tail (cdr tail)))
     alist))
 
+(defun make-temp-file (prefix &optional dir-flag)
+  "Create a temporary file.
+The returned file name (created by appending some random characters at the end
+of PREFIX, and expanding against `temporary-file-directory' if necessary,
+is guaranteed to point to a newly created empty file.
+You can then use `write-region' to write new data into the file.
+
+If DIR-FLAG is non-nil, create a new empty directory instead of a file."
+  (let (file)
+    (while (condition-case ()
+	       (progn
+		 (setq file
+		       (make-temp-name
+			(expand-file-name prefix temporary-file-directory)))
+		 (if dir-flag
+		     (make-directory file)
+		   (write-region "" nil file nil 'silent nil 'excl))
+		 nil)
+	    (file-already-exists t))
+      ;; the file was somehow created by someone else between
+      ;; `make-temp-name' and `write-region', let's try again.
+      nil)
+    file))
+
 ;;; subr.el ends here