* lisp/gnus: Use closures now that we activated `lexical-binding`scratch/lexical-gnus-rc

* lisp/gnus/nnml.el (nnml-request-accept-article):
* lisp/gnus/nnmairix.el (nnmairix-request-marks):
* lisp/gnus/nnmail.el (nnmail-get-new-mail-1):
* lisp/gnus/mm-view.el (mm-inline-image)
(mm-inline-text-html-render-with-w3m, mm-inline-text)
(mm-insert-inline, mm-inline-message):
* lisp/gnus/mm-partial.el (mm-inline-partial):
* lisp/gnus/mm-archive.el (mm-archive-dissect-and-inline):
* lisp/gnus/gnus-util.el (gnus-create-info-command):
* lisp/gnus/gnus-topic.el (gnus-topic-edit-parameters)
(gnus-topic-sort-topics-1):
* lisp/gnus/gnus-sum.el (gnus-summary-edit-article):
* lisp/gnus/gnus-srvr.el (gnus-server-edit-server):
* lisp/gnus/gnus-msg.el (gnus-inews-make-draft)
(gnus-inews-add-send-actions, gnus-summary-cancel-article)
(gnus-summary-supersede-article, gnus-summary-resend-message)
(gnus-configure-posting-styles):
* lisp/gnus/gnus-kill.el (gnus-execute):
* lisp/gnus/gnus-html.el (gnus-html-wash-images):
* lisp/gnus/gnus-group.el (gnus-group-edit-group)
(gnus-group-nnimap-edit-acl):
* lisp/gnus/gnus-draft.el (gnus-draft-edit-message, gnus-draft-setup):
* lisp/gnus/gnus-art.el (gnus-article-edit-part)
(gnus-mm-display-part, gnus-article-edit):
* lisp/gnus/gnus-agent.el (gnus-category-edit-predicate)
(gnus-category-edit-score, gnus-category-edit-groups):
Use closures instead of `(lambda ...).

* lisp/gnus/nnoo.el (noo--defalias): New function.
(nnoo-import-1, nnoo-define-skeleton-1): Use it to avoid `eval`.

1 files changed, 53 insertions, 48 deletions

diff --git a/lisp/gnus/gnus-msg.el b/lisp/gnus/gnus-msg.el
index 1bd62516b14..45e665be8c3 100644
--- a/lisp/gnus/gnus-msg.el
+++ b/lisp/gnus/gnus-msg.el
@@ -389,9 +389,10 @@ only affect the Gcc copy, but not the original message."
 ;;; Internal functions.
 
 (defun gnus-inews-make-draft (articles)
-  `(lambda ()
-     (gnus-inews-make-draft-meta-information
-      ,gnus-newsgroup-name ',articles)))
+  (let ((gn gnus-newsgroup-name))
+    (lambda ()
+      (gnus-inews-make-draft-meta-information
+       gn articles))))
 
 (autoload 'nnselect-article-number "nnselect" nil nil 'macro)
 (autoload 'nnselect-article-group "nnselect" nil nil 'macro)
@@ -578,8 +579,8 @@ instead."
   (when gnus-agent
     (add-hook 'message-header-hook #'gnus-agent-possibly-save-gcc nil t))
   (setq message-post-method
-	`(lambda (&optional arg)
-	   (gnus-post-method arg ,gnus-newsgroup-name)))
+	(let ((gn gnus-newsgroup-name))
+	  (lambda (&optional arg) (gnus-post-method arg gn))))
   (message-add-action
    `(progn
       (setq gnus-current-window-configuration ',winconf-name)
@@ -820,8 +821,8 @@ prefix `a', cancel using the standard posting method; if not
 post using the current select method."
   (interactive (gnus-interactive "P\ny"))
   (let ((message-post-method
-	 `(lambda (arg)
-	    (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
+	 (let ((gn gnus-newsgroup-name))
+	   (lambda (_arg) (gnus-post-method (eq symp 'a) gn))))
 	(custom-address user-mail-address))
     (dolist (article (gnus-summary-work-articles n))
       (when (gnus-summary-select-article t nil nil article)
@@ -856,11 +857,12 @@ header line with the old Message-ID."
       (set-buffer gnus-original-article-buffer)
       (message-supersede)
       (push
-       `((lambda ()
-           (when (gnus-buffer-live-p ,gnus-summary-buffer)
-	     (with-current-buffer ,gnus-summary-buffer
-	       (gnus-cache-possibly-remove-article ,article nil nil nil t)
-	       (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
+       (let ((buf gnus-summary-buffer))
+         (lambda ()
+           (when (gnus-buffer-live-p buf)
+	     (with-current-buffer buf
+	       (gnus-cache-possibly-remove-article article nil nil nil t)
+	       (gnus-summary-mark-as-read article gnus-canceled-mark)))))
        message-send-actions)
       ;; Add Gcc header.
       (gnus-inews-insert-gcc))))
@@ -1387,11 +1389,12 @@ the message before resending."
     (add-hook 'message-header-setup-hook
 	      #'gnus-summary-resend-message-insert-gcc t)
     (add-hook 'message-sent-hook
-	      `(lambda ()
-		 (let ((rfc2047-encode-encoded-words nil))
-		   ,(if gnus-agent
-			'(gnus-agent-possibly-do-gcc)
-		      '(gnus-inews-do-gcc)))))
+	      (let ((agent gnus-agent))
+		(lambda ()
+		  (let ((rfc2047-encode-encoded-words nil))
+		    (if agent
+			(gnus-agent-possibly-do-gcc)
+		      (gnus-inews-do-gcc))))))
     (dolist (article (gnus-summary-work-articles n))
       (if no-select
 	  (with-current-buffer " *nntpd*"
@@ -1916,47 +1919,49 @@ this is a reply."
 		   ((eq 'eval (car result))
 		    #'ignore)
 		   ((eq 'body (car result))
-		    `(lambda ()
-		       (save-excursion
-			 (message-goto-body)
-			 (insert ,(cdr result)))))
+		    (let ((txt (cdr result)))
+		      (lambda ()
+			(save-excursion
+			  (message-goto-body)
+			  (insert txt)))))
 		   ((eq 'signature (car result))
                     (setq-local message-signature nil)
                     (setq-local message-signature-file nil)
-		    (if (not (cdr result))
-			#'ignore
-		      `(lambda ()
-			 (save-excursion
-			   (let ((message-signature ,(cdr result)))
-			     (when message-signature
-			       (message-insert-signature)))))))
+		    (let ((txt (cdr result)))
+		      (if (not txt)
+			  #'ignore
+			(lambda ()
+			  (save-excursion
+			    (let ((message-signature txt))
+			      (when message-signature
+			        (message-insert-signature))))))))
 		   (t
 		    (let ((header
 			   (if (symbolp (car result))
 			       (capitalize (symbol-name (car result)))
-			     (car result))))
-		      `(lambda ()
-			 (save-excursion
-			   (message-remove-header ,header)
-			   (let ((value ,(cdr result)))
-			     (when value
-			       (message-goto-eoh)
-			       (insert ,header ": " value)
-			       (unless (bolp)
-				 (insert "\n")))))))))
+			     (car result)))
+			  (value (cdr result)))
+		      (lambda ()
+			(save-excursion
+			  (message-remove-header header)
+			  (when value
+			    (message-goto-eoh)
+			    (insert header ": " value)
+			    (unless (bolp)
+			      (insert "\n"))))))))
 		  nil 'local))
       (when (or name address)
 	(add-hook 'message-setup-hook
-		  `(lambda ()
-                     (setq-local user-mail-address
-                                 ,(or (cdr address) user-mail-address))
-		     (let ((user-full-name ,(or (cdr name) (user-full-name)))
-			   (user-mail-address
-			    ,(or (cdr address) user-mail-address)))
-		       (save-excursion
-			 (message-remove-header "From")
-			 (message-goto-eoh)
-			 (insert "From: " (message-make-from) "\n"))))
+		  (let ((name (or (cdr name) (user-full-name)))
+		        (email (or (cdr address) user-mail-address)))
+		    (lambda ()
+                      (setq-local user-mail-address email)
+		      (let ((user-full-name name)
+			    (user-mail-address email))
+			(save-excursion
+			  (message-remove-header "From")
+			  (message-goto-eoh)
+			  (insert "From: " (message-make-from) "\n")))))
 		  nil 'local)))))
 
 (defun gnus-summary-attach-article (n)