1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
#
# target: libcsiphash.so
#
libcsiphash_symfile = join_paths(meson.current_source_dir(), 'libcsiphash.sym')
libcsiphash_private = static_library(
'csiphash-private',
[
'c-siphash.c',
],
c_args: [
'-fvisibility=hidden',
'-fno-common',
],
pic: true,
)
libcsiphash_shared = shared_library(
'csiphash',
objects: libcsiphash_private.extract_all_objects(),
install: not meson.is_subproject(),
soversion: 0,
link_depends: libcsiphash_symfile,
link_args: [
'-Wl,--no-undefined',
'-Wl,--version-script=@0@'.format(libcsiphash_symfile),
],
)
libcsiphash_dep = declare_dependency(
include_directories: include_directories('.'),
link_with: libcsiphash_private,
version: meson.project_version(),
)
if not meson.is_subproject()
install_headers('c-siphash.h')
mod_pkgconfig.generate(
libraries: libcsiphash_shared,
version: meson.project_version(),
name: 'libcsiphash',
filebase: 'libcsiphash',
description: project_description,
)
endif
#
# target: test-*
#
test_api = executable('test-api', ['test-api.c'], link_with: libcsiphash_shared)
test('API Symbol Visibility', test_api)
test_basic = executable('test-basic', ['test-basic.c'], dependencies: libcsiphash_dep)
test('Basic API Behavior', test_basic)
|
