dnl $Id$
dnl
dnl Copyright (c) 2002-2008
dnl         The Xfce development team. All rights reserved.
dnl
dnl Written for Xfce by Benedikt Meurer <benny@xfce.org>.
dnl

dnl ***************************
dnl *** Version information ***
dnl ***************************
m4_define([xdt_version_major], [4])
m4_define([xdt_version_minor], [7])
m4_define([xdt_version_micro], [2])
m4_define([xdt_version_nano], [])
m4_define([xdt_version_build], [@REVISION@])
m4_define([xdt_version_tag], [])
m4_define([xdt_version], [xdt_version_major().xdt_version_minor().xdt_version_micro()ifelse(xdt_version_nano(), [], [], [.xdt_version_nano()])ifelse(xdt_version_tag(), [git], [xdt_version_tag()-xdt_version_build()], [])])


dnl # DO NOT MODIFY ANYTHING BELOW THIS LINE, UNLESS YOU KNOW WHAT
dnl # YOU ARE DOING.


dnl ***************************
dnl *** Initialize autoconf ***
dnl ***************************
AC_INIT([xfce4-dev-tools], [xdt_version],
        [http://bugzilla.xfce.org/enter_bug.cgi?product=Xfce4-dev-tools])
AC_COPYRIGHT([Copyright (c) 2002-2008
        The Xfce development team. All rights reserved.

Written for Xfce by Benedikt Meurer <benny@xfce.org>.])
AC_REVISION([$Id$])

dnl substitute version info
AC_SUBST([VERSION_MAJOR], [xdt_version_major])
AC_SUBST([VERSION_MINOR], [xdt_version_minor])
AC_SUBST([VERSION_MICRO], [xdt_version_micro])
AC_SUBST([VERSION_NANO], [xdt_version_nano])
VERSION_REVISION=ifelse(xdt_version_tag(), [git], [xdt_version_tag()-xdt_version_build()], [])
AC_SUBST([VERSION_REVISION])

dnl ***************************
dnl *** Initialize automake ***
dnl ***************************
AM_INIT_AUTOMAKE([AC_PACKAGE_TARNAME()], [AC_PACKAGE_VERSION()])
AM_MAINTAINER_MODE()

dnl ********************************
dnl *** Check for basic programs ***
dnl ********************************
AC_PROG_INSTALL()

dnl **********************
dnl *** Generate files ***
dnl **********************
AC_OUTPUT([
Makefile
xfce4-dev-tools.spec
m4macros/Makefile
scripts/Makefile
scripts/xdt-autogen.in
])

dnl vi:set ts=2 sw=2 et ai: