# Copyright 2014 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/features.gni")
import("//build/config/jumbo.gni")
import("//third_party/protobuf/proto_library.gni")

jumbo_static_library("browser") {
  sources = [
    "autofill_log_router_factory.cc",
    "autofill_log_router_factory.h",
    "bad_message.cc",
    "bad_message.h",
    "content_autofill_driver.cc",
    "content_autofill_driver.h",
    "content_autofill_driver_factory.cc",
    "content_autofill_driver_factory.h",
    "content_autofill_router.cc",
    "content_autofill_router.h",
    "form_forest.cc",
    "form_forest.h",
    "form_forest_util_inl.h",
    "risk/fingerprint.cc",
    "risk/fingerprint.h",
  ]

  public_deps = [
    ":risk_proto",
    "//components/autofill/content/common/mojom",
    "//components/autofill/core/browser",
    "//components/autofill/core/common",
    "//components/keyed_service/content",
    "//content/public/common",
    "//mojo/public/cpp/bindings",
    "//skia",
    "//third_party/abseil-cpp:absl",
  ]
  deps = [
    "//base",
    "//base:i18n",
    "//components/autofill_assistant/core/public:public",
    "//components/os_crypt",
    "//components/prefs",
    "//components/profile_metrics",
    "//components/resources",
    "//components/strings",
    "//components/user_prefs",
    "//components/version_info",
    "//components/webauthn/core/browser",
    "//content/public/browser",
    "//gpu/config",
    "//mojo/public/cpp/system",
    "//net",
    "//ppapi/buildflags",
    "//services/device/public/cpp/geolocation",
    "//services/device/public/mojom",
    "//services/service_manager/public/cpp",
    "//sql",
    "//ui/base",
    "//ui/display",
    "//ui/gfx",
    "//ui/gfx/geometry",
    "//url",
  ]

  if (!is_android) {
    deps += [ "//components/webauthn/content/browser" ]
  }

  if (is_qtwebengine) {
    sources -= [
      "autofill_log_router_factory.cc",
      "autofill_log_router_factory.h",
    ]
  }
}

proto_library("risk_proto") {
  sources = [ "risk/proto/fingerprint.proto" ]
  proto_out_dir = "components/autofill/content/browser/risk/proto"
}

source_set("test_support") {
  testonly = true
  sources = [
    "content_autofill_driver_factory_test_api.cc",
    "content_autofill_driver_factory_test_api.h",
    "content_autofill_driver_test_api.h",
    "content_autofill_router_test_api.h",
    "form_forest_test_api.cc",
    "form_forest_test_api.h",
    "test_autofill_manager_injector.h",
  ]

  public_deps = [
    ":browser",
    "//content/public/browser",
    "//content/test:test_support",
  ]

  deps = [ "//base" ]
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "autofill_internals_log_router_unittest.cc",
    "content_autofill_driver_factory_unittest.cc",
    "content_autofill_driver_unittest.cc",
    "form_forest_unittest.cc",
  ]

  deps = [
    ":browser",
    ":test_support",
    "//base",
    "//components/autofill/content/common/mojom",
    "//components/autofill/core/browser",
    "//components/autofill/core/browser:test_support",
    "//components/autofill/core/common",
    "//components/version_info",
    "//content/public/browser",
    "//content/public/common",
    "//content/test:test_support",
    "//mojo/public/cpp/system",
    "//net:test_support",
    "//services/service_manager/public/cpp",
    "//testing/gmock",
    "//testing/gtest",
  ]
}