summaryrefslogtreecommitdiff
path: root/src/serialport/serialport-lib.pri
blob: bb12df27ef403fc3f17afe74877f53eae79ade36 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
INCLUDEPATH += $$PWD

unix:qtConfig(libudev) {
    DEFINES += LINK_LIBUDEV
    INCLUDEPATH += $$QMAKE_INCDIR_LIBUDEV
    LIBS_PRIVATE += $$QMAKE_LIBS_LIBUDEV
}

PUBLIC_HEADERS += \
    $$PWD/qserialportglobal.h \
    $$PWD/qserialport.h \
    $$PWD/qserialportinfo.h

PRIVATE_HEADERS += \
    $$PWD/qserialport_p.h \
    $$PWD/qserialportinfo_p.h

SOURCES += \
    $$PWD/qserialport.cpp \
    $$PWD/qserialportinfo.cpp

win32:!wince* {
    SOURCES += \
        $$PWD/qserialport_win.cpp \
        $$PWD/qserialportinfo_win.cpp \
        $$PWD/qwinoverlappedionotifier.cpp

    PRIVATE_HEADERS += \
        $$PWD/qwinoverlappedionotifier_p.h

    LIBS_PRIVATE += -lsetupapi -ladvapi32
}

unix {
    SOURCES += \
        $$PWD/qserialport_unix.cpp

    osx {
        SOURCES += \
            $$PWD/qserialportinfo_osx.cpp

        LIBS_PRIVATE += -framework IOKit -framework CoreFoundation
    } else:freebsd {
        SOURCES += \
            $$PWD/qserialportinfo_freebsd.cpp
    } else {
        SOURCES += \
            $$PWD/qserialportinfo_unix.cpp
    }
}

HEADERS += $$PUBLIC_HEADERS $$PRIVATE_HEADERS