blob: 39df9754b7d995515a3f9e621e02925e8c11cf3b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
include(qtcreator.pri)
#version check qt
!minQtVersion(4, 7, 4) {
message("Cannot build Qt Creator with Qt version $${QT_VERSION}.")
error("Use at least Qt 4.7.4.")
}
include(doc/doc.pri)
TEMPLATE = subdirs
CONFIG += ordered
SUBDIRS = src share lib/qtcreator/qtcomponents
unix:!macx:!isEmpty(copydata):SUBDIRS += bin
OTHER_FILES += dist/copyright_template.txt \
$$files(dist/changes-*)
macx {
APPBUNDLE = "$$OUT_PWD/bin/Qt Creator.app"
deployqt.commands = macdeployqt "$${APPBUNDLE}" \
-executable="$${APPBUNDLE}/Contents/MacOS/qmlpuppet.app/Contents/MacOS/qmlpuppet" \
-executable="$${APPBUNDLE}/Contents/Resources/qtpromaker" \
-executable="$${APPBUNDLE}/Contents/MacOS/qmlprofiler"
deployqt.depends = default
bindist.commands = 7z a -mx9 $$OUT_PWD/qtcreator$(INSTALL_POSTFIX).7z "$$OUT_PWD/bin/Qt Creator.app/"
dmg.commands = $$PWD/scripts/makedmg.sh $$OUT_PWD/bin qt-creator$(INSTALL_POSTFIX).dmg
QMAKE_EXTRA_TARGETS += dmg
} else {
deployqt.commands = $$PWD/scripts/deployqt.py -i $(INSTALL_ROOT)
win32:deployqt.commands ~= s,/,\\\\,g
deployqt.depends = install
bindist.commands = 7z a -mx9 $$OUT_PWD/qtcreator$(INSTALL_POSTFIX).7z $(INSTALL_ROOT)
win32:bindist.commands ~= s,/,\\\\,g
}
bindist.depends = deployqt
QMAKE_EXTRA_TARGETS += deployqt bindist
|