%
% (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
%
\section[CodeGen]{@CodeGen@: main module of the code generator}

This module says how things get going at the top level.

@codeGen@ is the interface to the outside world.  The \tr{cgTop*}
functions drive the mangling of top-level bindings.

%************************************************************************
%*									*
\subsection[codeGen-outside-interface]{The code generator's offering to the world}
%*									*
%************************************************************************

\begin{code}
module CodeGen ( codeGen ) where

#include "HsVersions.h"

import StgSyn
import CgMonad
import AbsCSyn
import CLabel		( CLabel, mkSRTLabel, mkClosureLabel )

import PprAbsC		( dumpRealC )
import AbsCUtils	( mkAbstractCs, mkAbsCStmts, flattenAbsC )
import CgBindery	( CgIdInfo, addBindC, addBindsC )
import CgClosure	( cgTopRhsClosure )
import CgCon		( cgTopRhsCon )
import CgConTbls	( genStaticConBits )
import ClosureInfo	( mkClosureLFInfo )
import CmdLineOpts	( opt_SccProfilingOn, opt_EnsureSplittableC, 
			  opt_D_dump_absC,    opt_SccGroup
			)
import CostCentre       ( CostCentre, CostCentreStack )
import FiniteMap	( FiniteMap )
import Id               ( Id, idName )
import Module           ( Module, moduleString, ModuleName, moduleNameString )
import PrimRep		( getPrimRepSize, PrimRep(..) )
import Type             ( Type )
import TyCon            ( TyCon, isDataTyCon )
import Class		( Class, classTyCon )
import BasicTypes	( TopLevelFlag(..) )
import UniqSupply	( mkSplitUniqSupply )
import ErrUtils		( dumpIfSet )
import Util
import Panic		( assertPanic )
\end{code}

\begin{code}


codeGen :: Module		-- Module name
	-> [ModuleName]		-- Import names
	-> ([CostCentre],	-- Local cost-centres needing declaring/registering
	    [CostCentre],	-- "extern" cost-centres needing declaring
	    [CostCentreStack])  -- Pre-defined "singleton" cost centre stacks
	-> [TyCon] -> [Class]	-- Local tycons and classes
	-> [(StgBinding,[Id])]	-- Bindings to convert, with SRTs
	-> IO AbstractC		-- Output

codeGen mod_name imported_modules cost_centre_info
	tycons classes stg_binds
  = mkSplitUniqSupply 'f'	>>= \ fl_uniqs  -> -- absC flattener
    let
	datatype_stuff 	  = genStaticConBits cinfo data_tycons
	code_stuff     	  = initC cinfo (cgTopBindings maybe_split stg_binds)
	cost_centre_stuff = mkCostCentreStuff mod_name imported_modules cost_centre_info

	abstractC = mkAbstractCs [ cost_centre_stuff, 
				   datatype_stuff,
				   code_stuff ]

	flat_abstractC = flattenAbsC fl_uniqs abstractC
    in
    dumpIfSet opt_D_dump_absC "Abstract C" (dumpRealC abstractC)	>>
    return flat_abstractC

  where
    data_tycons = filter isDataTyCon (tycons ++ map classTyCon classes)
			-- Generate info tables  for the data constrs arising
			-- from class decls as well

    maybe_split = if opt_EnsureSplittableC 
		  then CSplitMarker 
		  else AbsCNop
    cinfo       = MkCompInfo mod_name
\end{code}

Cost-centre profiling:
Besides the usual stuff, we must produce:

* Declarations for the cost-centres defined in this module;
* Code to participate in "registering" all the cost-centres
  in the program (done at startup time when the pgm is run).

(The local cost-centres involved in this are passed
into the code-generator, as are the imported-modules' names.)

\begin{code}
mkCostCentreStuff mod_name import_names (local_CCs, extern_CCs, singleton_CCSs)
  | not opt_SccProfilingOn = AbsCNop
  | otherwise = mkAbstractCs (
		    map (CCostCentreDecl True)   local_CCs ++
		    map (CCostCentreDecl False)  extern_CCs ++
		    map CCostCentreStackDecl     singleton_CCSs ++
		    mkCcRegister local_CCs singleton_CCSs import_names
		)

  where
    mkCcRegister ccs cc_stacks import_names
      = let
	    register_ccs     = mkAbstractCs (map mk_register ccs)
	    register_imports
	      = foldr (mkAbsCStmts . mk_import_register) AbsCNop import_names
	    register_cc_stacks = mkAbstractCs (map mk_register_ccs cc_stacks)
	in
	[
	    CCallProfCCMacro SLIT("START_REGISTER_CCS") 
	       [ CLitLit (_PK_ ("_reg" ++ moduleString mod_name)) AddrRep],
	    register_ccs,
	    register_cc_stacks,
	    register_imports,
	    CCallProfCCMacro SLIT("END_REGISTER_CCS") []
	]
      where
	mk_register cc
	  = CCallProfCCMacro SLIT("REGISTER_CC") [mkCCostCentre cc]

	mk_register_ccs ccs
	  = CCallProfCCMacro SLIT("REGISTER_CCS") [mkCCostCentreStack ccs]

	mk_import_register import_name
	  = CCallProfCCMacro SLIT("REGISTER_IMPORT") 
	      [CLitLit (_PK_ ("_reg" ++ moduleNameString import_name)) AddrRep]
\end{code}

%************************************************************************
%*									*
\subsection[codegen-top-bindings]{Converting top-level STG bindings}
%*									*
%************************************************************************

@cgTopBindings@ is only used for top-level bindings, since they need
to be allocated statically (not in the heap) and need to be labelled.
No unboxed bindings can happen at top level.

In the code below, the static bindings are accumulated in the
@MkCgState@, and transferred into the ``statics'' slot by @forkStatics@.
This is so that we can write the top level processing in a compositional
style, with the increasing static environment being plumbed as a state
variable.

\begin{code}
cgTopBindings :: AbstractC -> [(StgBinding,[Id])] -> Code

cgTopBindings split bindings = mapCs (cgTopBinding split) bindings

cgTopBinding :: AbstractC -> (StgBinding,[Id]) -> Code

cgTopBinding split ((StgNonRec name rhs), srt)
  = absC split		  	`thenC`
    absC (mkSRT srt_label srt) 	`thenC`
    setSRTLabel srt_label (
    cgTopRhs name rhs	  	`thenFC` \ (name, info) ->
    addBindC name info
    )
  where
    srt_label = mkSRTLabel (idName name)

cgTopBinding split ((StgRec pairs@((name,rhs):_)), srt)
  = absC split		  	`thenC`
    absC (mkSRT srt_label srt) 	`thenC`
    setSRTLabel srt_label (
    fixC (\ new_binds -> addBindsC new_binds	`thenC`
			 mapFCs ( \ (b,e) -> cgTopRhs b e ) pairs
    )			  `thenFC` \ new_binds ->
    addBindsC new_binds
    )
  where
    srt_label = mkSRTLabel (idName name)

mkSRT :: CLabel -> [Id] -> AbstractC
mkSRT lbl []  = AbsCNop
mkSRT lbl ids = CSRT lbl (map (mkClosureLabel . idName) ids)

-- Urgh!  I tried moving the forkStatics call from the rhss of cgTopRhs
-- to enclose the listFCs in cgTopBinding, but that tickled the
-- statics "error" call in initC.  I DON'T UNDERSTAND WHY!

cgTopRhs :: Id -> StgRhs -> FCode (Id, CgIdInfo)
	-- the Id is passed along for setting up a binding...

cgTopRhs bndr (StgRhsCon cc con args)
  = forkStatics (cgTopRhsCon bndr con args (all zero_size args))
  where
    zero_size atom = getPrimRepSize (getArgPrimRep atom) == 0

cgTopRhs bndr (StgRhsClosure cc bi srt fvs upd_flag args body)
  = ASSERT(null fvs) -- There should be no free variables
    getSRTLabel `thenFC` \srt_label ->
    let lf_info = 
	  mkClosureLFInfo bndr TopLevel [{-no fvs-}] upd_flag args srt_label srt
    in
    forkStatics (cgTopRhsClosure bndr cc bi args body lf_info)
\end{code}