AC_INIT(new-control-center)

AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(control-center, 1.3.0)

AM_MAINTAINER_MODE

dnl
dnl let applications configure for gnome
dnl
gnome_cv_use_gnome=yes


AM_ACLOCAL_INCLUDE(macros)
GNOME_INIT
GNOME_COMPILE_WARNINGS

AC_ISC_POSIX
AC_PROG_CC
AC_STDC_HEADERS
AC_ARG_PROGRAM
AM_PROG_LIBTOOL
AM_PROG_LEX
AC_PROG_YACC

dnl utility conditional
AM_CONDITIONAL(FALSE, test "x" = "y")

ALL_LINGUAS="ca cs da de el en_GB es et fi fr ga gl hr hu it ja ko lt nl no pl pt pt_BR ro ru sl sv tr uk zh_CN.GB2312 zh_TW.Big5"
AM_GNOME_GETTEXT

GNOME_XML_CHECK
XML_CFLAGS=`gnome-config --cflags xml`
AC_SUBST(XML_CFLAGS)

AM_PATH_LIBGLADE(,,"gnome")

AC_SUBST(CFLAGS)
AC_SUBST(LDFLAGS)

AC_CHECK_HEADERS(dlfcn.h dl.h)
AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl",[
AC_CHECK_LIB(dld, shl_load, DL_LIB="-ldld",[
AC_CHECK_FUNCS(dlopen, DL_LIB="",
AC_MSG_ERROR(Dynamic linking is not available on this platform.  Some
apps, like panel, will not run properly.))
])])
AC_SUBST(DL_LIB)

AC_CHECK_FUNCS(usleep)

dnl keyboard-properties-capplet
AC_CHECK_HEADERS(X11/extensions/xf86misc.h, XF86MISC_LIBS="-lXxf86misc")
AC_SUBST(XF86MISC_LIBS)

AM_PATH_LIBGLADE(,AC_MSG_ERROR([You must have LibGlade installed.]), gnome)

dnl esd-manager
have_libesd=no
AM_PATH_ESD(,have_libesd=yes,
[AC_MSG_WARN([*** \`esd-manager' will not be built ***])])
AM_CONDITIONAL(HAVE_LIBESD, test yes = $have_libesd)
if test "$have_libesd" = yes; then
	AC_DEFINE(HAVE_ESD)
	AC_DEFINE(HAVE_LIBESD)
fi

dnl session-properties
AM_CONDITIONAL(SESSION, test "$GNOME_HAVE_SM" = true)

AM_PATH_IMLIB(1.8.2, , [
echo "ERROR: Needs a system with Imlib 1.8.2 or higher"
echo "You can obtain it from:"
echo "ftp://ftp.enlightenment.org/pub/enlightenment/"
echo "ftp://www.rasterman.com/pub/enlightenment/"
echo "ftp://ftp.labs.redhat.com/pub/imlib/"
AC_MSG_ERROR([Fatal Error: no Imlib detected.])])

AC_OUTPUT([
control-center.spec
Makefile
po/Makefile.in
new-control-center/Makefile
libcapplet/Makefile
capplets/Makefile
capplets/mouse-properties/Makefile
capplets/mime-type/Makefile
capplets/desktop-links/Makefile
capplets/background-properties/Makefile
capplets/new-screensaver-properties/Makefile
capplets/new-screensaver-properties/screensavers/Makefile
capplets/session-properties/Makefile
capplets/sound-properties/Makefile
capplets/bell-properties/Makefile
capplets/theme-switcher/Makefile
capplets/ui-properties/Makefile
capplets/url-properties/Makefile
capplets/gnome-edit-properties/Makefile
capplets/wm-properties/Makefile
capplets/wm-properties/wm-desktops/Makefile
idl/Makefile
intl/Makefile])